未保存在加载功能之外的数组-ActionScript 3和XML

Question

First of all, I'm really sorry I'm asking this again but after reading through the top 3 answers to this problem, none seemed to have given me any resolution.

I'm trying to load in an XML file containing level data into my AS3 game. It's quite simple, the XML is dumped into an array that I've checked through and through - the length, size, and each and every variable inside of it is a-okay.

The only real problem is that my array gets purged whenever I refer to it outside of the function. I've read that it's related to asynchronous nature of ActionScript and that I need a separate handler... but, perhaps I am simply an idiot, I do posses such a handler.

Could anyone take a peek at this here piece of code and perhaps bonk me on the head with a big stick as to what I made wrong?

package{
import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.events.Event;
import flash.display.MovieClip;

public class LevelLoader extends MovieClip{

    private var _root:MovieClip;

    public var lvlArray:Array = new Array(); //Tablica (wektor) trzymający nam ułożenie mapy.

    private var xmlFile:XML;// The XML File Holder, duuh.
    private var urlLoader:URLLoader = new URLLoader();//The XML File Loader, duuuh.

    private var variant:int;

    public function LevelLoader(v:int){
        loadXML();
        variant = v;
        trace('Poza: '+lvlArray.length);
    }

    // Dośc vokalidów. Ale przeklejam z starego kodu.
    private function loadXML(file:String = "XMLG.xml"):void
    {
        urlLoader.addEventListener(Event.COMPLETE, parseXML);
        urlLoader.load(new URLRequest(file));
    }

    private function parseXML(e:Event):void
    {
        xmlFile = new XML(e.target.data);
        loadArray(variant,xmlFile);
    }

    private function loadArray(vars:int,xmlInput:XML):void
    {
        //trace(xmlInput.lay[vars].children().length());
        var layLength:int = xmlInput.lay[vars].children().length();
        for (var i:int = 0; i<layLength; i++){
            this.lvlArray.push(xmlInput.lay[vars].field[i].@type);
            //trace(xmlInput.lay[vars].field[i].@type);
             }
        saveArray(lvlArray);
        trace('W: '+lvlArray.length);
    }

    private function saveArray(arr:Array):void{
        lvlArray = arr;
    }

}

}

PS Yes those are comments in mixed Polish and English. Please, make nothing of it.

Answer 1

I don't think your array is getting "purged," I think it's possible that you're attempting to reference the array before parseXML has been called.

Since you've only posted the code for LevelLoader , I'll assume that somewhere else, you're attempting to reference LevelLoader.lvlArray . You should hold off on this action until you've received some sort of "complete" or "loaded" event that you will dispatch from your loadArray method (there's no real need for your saveArray method):

package{
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.display.MovieClip;

    public class LevelLoader extends MovieClip{

        private var _root:MovieClip;

        public var lvlArray:Array = new Array(); //Tablica (wektor) trzymajacy nam ulozenie mapy.

        private var xmlFile:XML;// The XML File Holder, duuh.
        private var urlLoader:URLLoader = new URLLoader();//The XML File Loader, duuuh.

        private var variant:int;

        public function LevelLoader(v:int){
            variant = v;
            trace('Poza: '+lvlArray.length);
        }

        // Dosc vokalidów. Ale przeklejam z starego kodu.
        public function loadXML(file:String = "XMLG.xml"):void
        {
            urlLoader.addEventListener(Event.COMPLETE, parseXML);
            urlLoader.load(new URLRequest(file));
        }

        private function parseXML(e:Event):void
        {
            xmlFile = new XML(e.target.data);
            loadArray(variant,xmlFile);
        }

        private function loadArray(vars:int,xmlInput:XML):void
        {
            //trace(xmlInput.lay[vars].children().length());
            var layLength:int = xmlInput.lay[vars].children().length();
            for (var i:int = 0; i<layLength; i++){
                this.lvlArray.push(xmlInput.lay[vars].field[i].@type);
                //trace(xmlInput.lay[vars].field[i].@type);
            }
            trace('W: '+lvlArray.length);

            dispatchEvent(new Event(Event.COMPLETE));
        }

    }
}

Wherever you're instantiating LevelLoader , you'll want to listen for this event:

var lvlLoader:LevelLoader = new LevelLoader(1);
lvlLoader.addEventListener(Event.COMPLETE, onLevelLoaded);
lvlLoader.loadXML();

private function onLevelLoaded(e:Event):void {
    var lvlLoader:LevelLoader = e.target as LevelLoader;
    lvlLoader.removeEventListener(Event.COMPLETE, onLevelLoaded);

    // you may NOW reference lvlLoader.lvlArray
    trace(lvlLoader.lvlArray.length);
}

Note that I've made the loadXML method public so that it may be called after you've added the event listener.