使用SAS变量将参数传递给SAS函数

Question

I want to calculate the maximum of a list of SAS variables, where the list is determined by another variable present in the dataset. That is,

| var_1 | var_2 | var_3 | var_4 | maximum till | formula used         | var_output |
|-------|-------|-------|-------|--------------|----------------------|------------|
| 3     | 6     | 9     | 12    | 4            | =max(of var_1-var_4) | 12         |
| 1     | 10    | 100   | 1000  | 2            | =max(of var_1-var_2) | 10         |
| 5     | 15    | 25    | 35    | 3            | =max(of var_1-var_3) | 25         |

Appreciate any help. Thanks :)

Answer 1

Use a do loop and a rolling maximum:

data want;
    set have;
    array vars{4} var1-var4;
    do i = 1 to max_till;
        var_out = max(vars{i},var_out);
    end;
run;

Answer 2

The FCMP solution. This is similar to user667489's solution, but implemented as a function. This will only work in 9.4, and possibly only 9.4 TS1M0+.

data have;                       *some data;
input var1-var4 varmax;
datalines;
3 6 9 12 4
1 10 100 1000 2
5 15 25 35 3
;;;;
run;

proc fcmp outlib=work.funcs.func; *store functions here;
function maxof(mxarr[*],maxlim);  *returns numeric;
    do _i = 1 to maxlim;
      _max = max(mxarr[_i],_max);
    end;
    return(_max);
endsub;
run;

options cmplib=work.funcs;        *define where functions come from;    
data want;
set have;
array vars var1-var4;
varout = maxof(vars,varmax);      *use function (pass array by reference);
run;