在Unboxed Vectors上记忆函数会导致它挂起

Question

I'm playing with Vectors and Unboxed Vectors, with a fairly simple program. I'm enumerating all integers whose only factors are 2,3 & 5.

I thought I'd try memoising it over Data.Vector which worked and was super easy. So I thought I'd try Data.Vector.Unboxed . However, it hangs when z is [0..5] , but not when z is [0..4] and I'm not sure why. The difference between the two is that 5 involves a mutually recursive call.

What's going wrong here?

import Data.Vector.Unboxed as UV

memoisingCandidateUV :: UV.Vector Bool
memoisingCandidateUV = UV.map isCandidateUV z

isCandidateUV :: Int -> Bool
isCandidateUV 0 = False
isCandidateUV n
    | n2r == 0 = n2q == 1 || memoisingCandidateUV UV.! n2q
    | n3r == 0 = n3q == 1 || memoisingCandidateUV UV.! n3q
    | n5r == 0 = n5q == 1 || memoisingCandidateUV UV.! n5q
    | otherwise = False
    where
      (n2q, n2r) = n `quotRem` 2
      (n3q, n3r) = n `quotRem` 3
      (n5q, n5r) = n `quotRem` 5

Answer 1

All unboxed containers are deep-strict, which means you can't use them for lazy memoisation: before any element is accessible as memoised, you have to have all of them evaluated.

As to why this is so: when you have a normal lazy thunk in Haskell, it's the box that carries this information about that the value is not yet in NF right now, but to make it so you can execute this piece of code . After that's been done the box is basically just a pointer to the result.
That's a great help in many situations, but it's not for free memory- or performance-wise: that's precisely the overhead which unboxed containers remove, by directly storing the result information in a tight array.

Answer 2

In this specific case (all recursive calls are to smaller indices, and n can be reconstructed from the already-computed vector), you can use constructN (it works iteratively rather than relying on laziness):

import Data.Vector.Unboxed as UV

memoisingCandidateUV :: UV.Vector Bool
memoisingCandidateUV = UV.constructN 100 isCandidateUV

isCandidateUV :: UV.Vector Bool -> Bool
isCandidateUV vec = result
  where
    n = UV.length vec

    result
      |   n == 0 = False
      | n2r == 0 = n2q == 1 || vec UV.! n2q
      | n3r == 0 = n3q == 1 || vec UV.! n3q
      | n5r == 0 = n5q == 1 || vec UV.! n5q
      | otherwise = False

    (n2q, n2r) = n `quotRem` 2
    (n3q, n3r) = n `quotRem` 3
    (n5q, n5r) = n `quotRem` 5