Windows批处理文件-一次处理一个文件

Question

Odd question - but it's driving me a bit crazy. I have a directory where multiple files can be dumped via FTP, then I need to process them one at time. So basically in this directory I could have 1.txt, 2.txt, 3.txt etc then I need to:

copy the file to an archive (if exist copy to archive)

move the file to one specific filename one at a time - data.txt <--- this is what's getting me

run a command on a legacy backend system client using that specific filename (data.txt)

run another command on legacy client using data.txt

delete data.txt

Move on to the next file and repeat

So far I've tried several methods of do loops without any luck - they all get hung up on trying to rename multiple files into one file, and that just kills me. I'd long ago since given up on batch files but annoyingly, this application has to use windows, and Server 2003 to boot.

EDIT: Here's what I've tried-

1. This works to do one file at a time:

   if exist c:\\jail\\ftp*.txt copy c:\\jail\\ftp*.txt w:\\scans\\archive*.txt
   if exist c:\\jail\\ftp*.txt move c:\\jail\\ftp*.txt w:\\data.txt
   if exist w:\\data.txt C:\\temp\\rmtcmdb.exe
   if exist w:\\data.txt del w:\\data.txt

2. I've tried multiple for loops without success, here is the latest (NOTE - I'm just trying to get past the move stage on this one, once I'm done with that I'll add in the rest):

   setlocal ENABLEDELAYEDEXPANSION
   FOR /f %%a IN ("c:\\jail\\ftp\\") DO (
   CALL SET /A x = !x! +1
   if !x! == 1 (
   CALL copy %%aw:\\scans\\archive*.txt
   CALL move %%aw:\\data.txt
   )
   )

I've also tried some very basic for loops, and again - nothing is getting past the move stage.

Any suggestions?

Answer 1

@echo off

    setlocal enableextensions

    for %%a in ("c:\jail\ftp*.txt") do (

        set "fileName=%%~na"
        setlocal enabledelayedexpansion
        copy "%%~fa" "w:\scans\!fileName:*ftp=archive!%%~xa"
        endlocal

        move /y "%%~fa" "w:\data.txt"

        start "" /wait "c:\temp\rmtcmdb.exe"

        if exist "w:\data.txt" del /s "w:\data.txt" >nul 2>nul 
    )