如何从Clojure中的文件读取多个变量？

Question

Coming from OOP, I'm having a bit of trouble adjusting to the immutability of Clojure.

What I want to do is grab some variables from a file, and store each variable and its data to a map.

In other words, I want to 'extract' a map from a text file.

As an example, the file would look like this:

username: michael
password: foo123
email: barfoo@gmail.com

My question is, how do I convert the above file into a map like this: (?)

{:username "michael", :password "foo123", :email "barfoo@gmail.com"}

This is what I had so far, but I have no idea how to get multiple variables:

(with-open [rdr (reader "/path/to/file.txt")]
  (doseq [line (line-seq rdr)]
    // make map here somehow? ))

Answer 1

Try this:

(->> (clojure.string/split (slurp "yourfile.txt") #"\n")
     (map #(clojure.string/split % #":"))
     (map (fn [[k v]] [(keyword k) v]))
     (into {}))

slurp function read a file and returns a string of file contents. It's useful to read text file into a string. After that, split the string by \\n , which retrun a sequence of strings. Then split each string by : .

You can check each step in the REPL and see the result of each step, like this:

user=> (->> (clojure.string/split (slurp "yourfile.txt") #"\n"))
["username: michael" "password: foo123" "email: barfoo@gmail.com"]
user=> (->> (clojure.string/split (slurp "yourfile.txt") #"\n")
            (map #(clojure.string/split % #":\s*")))
(["username" "michael"] ["password" "foo123"] ["email" "barfoo@gmail.com"])
user=> (->> (clojure.string/split (slurp "yourfile.txt") #"\n")
            (map #(clojure.string/split % #":\s*"))
            (map (fn [[k v]] [(keyword k) v])))
([:username "michael"] [:password "foo123"] [:email "barfoo@gmail.com"])
user=> (->> (clojure.string/split (slurp "yourfile.txt") #"\n")
            (map #(clojure.string/split % #":\s*"))
            (map (fn [[k v]] [(keyword k) v]))
            (into {}))
{:username "michael", :password "foo123", :email "barfoo@gmail.com"}