如何将查询结果添加到组合框

Question

Here I am trying to add results of query into combobox but am able to add to combobox wherever the query result restricted to one value but more than not able to add it.

Please help me on this issue.

Private Sub CommandButton1_Click()
Dim i As Integer
Dim rs As ADODB.Recordset
Dim vendor As String
Dim season As String
Dim ms As String
Dim JS As String

With Application.FileDialog(msoFileDialogFilePicker)
.AllowMultiSelect = False
.Show
For i = 1 To .SelectedItems.Count
Me.TextBox1.Value = .SelectedItems(i)
Next
End With
fpath = Me.TextBox1.Value
'settings.savesettings
'fpath = UserForm1.TextBox1.Value
vendor = "Select distinct [Vendor Code] from [Data$] where [Vendor Code] is not null"
season = "Select distinct [Season] from [Data$] where [Season] is not null"
ms = "Select distinct [Material Style] from [Data$] where [Material Style] is not null"
JS = "Select distinct [JDE Style] from [Data$] where [JDE Style] is not null"

Call connectiontosql.connectiontosql
Set rs = New ADODB.Recordset

rs.Open vendor, cn, adOpenKeyset, adLockOptimistic
For i = 0 To rs.RecordCount - 1
Me.ComboBox1.AddItem rs.Fields(i).Value
Next
rs.Close

rs.Open season, cn, adOpenKeyset, adLockOptimistic
For i = 0 To rs.RecordCount - 1
Me.ComboBox2.AddItem rs.Fields(i).Value
Next
rs.Close
Call connectiontosql.connectiontosql

rs.Open ms, cn, adOpenKeyset, adLockOptimistic

i = 1
Do Until i = rs.RecordCount
Me.ComboBox3.AddItem rs.Fields(i).Value
i = i + 1
Loop
Call connectiontosql.connectiontosql

rs.Open JS, cn, adOpenKeyset, adLockOptimistic
For i = 0 To rs.RecordCount - 1
Me.ComboBox4.AddItem rs.Fields(i).Value
Next
rs.Close

End Sub

Answer 1

Note that RecordCount doesn't always return what you want, so it's best to avoid it in loops unless you really need it (in which case check that your providor and cusortype support RecordCount). Also, you're attempting to loop through the records (rows) of the recordset, but you're reading the Fields (columns). Generally, to loop through a recordset and add the first field of each record to a combobox, it would look like this:

If Not rs.EOF And Not rs.BOF Then
    Do
        Me.combobox3.AddItem rs.Fields(0).Value
        rs.MoveNext
    Loop Until rs.EOF
End If

When you open rs, the cursor is on the first record. If there are are no records, both EOF and BOF will be true. In the Do Loop, rs.MoveNext advances the cursor to the next record.

rs.Fields(0).Value returns the value of the first field for the record the cursor is on. If you need a different field, specify it by number (starting with zero) or by name (in quotes).