在Perl中将哈希值用作类别

Question

I'm reading two tab separated files into two hashes, files looks like this:

apple fruit
pear  fruit
carrot vegetable
potato vegetable
peach fruit

and

apple 23
pear  34
carrot 12
potato 45
peach 12

I want to pick up only vegetable and get their numbers. Is there any smarter way than through the for cycle to do this? And if I want to create two new hashes %fruits and %vegetable, do I really have to do it like:

foreach (keys %kinds_hash) {
   if ($kinds_hash{$_} =~ "vegetable") {
      $vegetable{$_} = $numbers_hash{$_};
   } elsif ($kinds_hash{$_} =~ "fruit") {
      $fruit{$_} = $numbers_hash{$_};
   }
}

Answer 1

There's nothing wrong with iterating on all the values.

However, if you're going to be doing it often, then perhaps it would be useful to create a new data structure that contains an array of names based off type.

use strict;
use warnings;

# Data in Paragraph mode
local $/ = '';

my %counts = split ' ', <DATA>;
my %types = split ' ', <DATA>;

# Create a structure that puts each type into an array
my %group_by_type;
while (my ($name, $type) = each %types) {
    push @{$group_by_type{$type}}, $name
}

# Show all Veges
for my $fruit (@{$group_by_type{vegetable}}) {
    print "$fruit $counts{$fruit}\n";
}

__DATA__
apple 23
pear 34
carrot 12
potato 45
peach 12

apple fruit
pear fruit
carrot vegetable
potato vegetable
peach fruit

Outputs:

carrot 12
potato 45

To learn more about Hashes of Arrays and other data structures, check out perldsc - Perl Data Structures Cookbook

Answer 2

You should structure your data so that all the ways you want to access it are made as simple as possible.

You want to access all the items in the vegetable category, and the numbers for all of those items. To make that simple I would build two hashes - one relating the names of the items to their number and category, and another relating the categories to all the names in each category.

This code does just that and uses Data::Dump to show you what has been built.

use strict;
use warnings;
use autodie;

my %items;
my %categories;

open my $fh, '<', 'numbers.tabsep';
while (<$fh>) {
  next unless /\S/;
  chomp;
  my ($name, $number) = split /\t/;
  $items{$name}[0] = $number;
}

open $fh, '<', 'categories.tabsep';
while (<$fh>) {
  next unless /\S/;
  chomp;
  my ($name, $cat) = split /\t/;
  $items{$name}[1] = $cat;
  push @{ $categories{$cat} }, $name;
}

use Data::Dump;
dd \%items;
dd \%categories;

output

{
  apple  => [23, "fruit"],
  carrot => [12, "vegetable"],
  peach  => [12, "fruit"],
  pear   => [34, "fruit"],
  potato => [45, "vegetable"],
}
{
  fruit => ["apple", "pear", "peach"],
  vegetable => ["carrot", "potato"],
}

Now, to answer the question "I want to pick up only vegetables and get their numbers" we just loop over the vegetable element of the %categories hash, and use the %items hash to determine their numbers. Like this

for my $item (@{ $categories{vegetable} }) {
  printf "%s %d\n", $item, $items{$item}[0];
}

output

carrot 12
potato 45

Tool completed successfully

Answer 3

You can create hash of hashes, just one nested data structure where the inner key will be your category and the value will be another hash whose key will be type and value be the number.

Following program does that:

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my %data; 

open my $fh_one, '<', 'file1';
while(<$fh_one>) {
    next unless /\S+/;
    chomp;
    my ($type, $category) = split /\t/;
    $data{$category}{$type} = undef;
}
close($fh_one);

open my $fh_two, '<', 'file2';
OUTER: while(<$fh_two>) {
    next unless /\S+/;
    chomp;
    my ($type, $number) = split /\t/;
    for my $category (keys %data) {
        for my $item (keys %{ $data{$category} }) {
            $data{$category}{$item} = $number and next OUTER if $item eq $type;
        }
    }
}
close($fh_two);

#print Dumper \%data;

while (my ($type, $number) = each $data{'vegetable'}) {
    print "$type $number\n";
}

If you uncomment the print Dumper \\%data; you will see the nested data structure. It will look like the following:

$VAR1 = {
          'fruit' => {
                       'peach' => '12',
                       'apple' => '23',
                       'pear' => '34'
                     },
          'vegetable' => {
                           'carrot' => '12',
                           'potato' => '45'
                         }
        };

The output of the above program is:

carrot 12
potato 45