如何在WHERE语句中使用宏变量按字符串对数据进行子集化？ （SAS 9.3）

Question

I want to be able to loop PROC SQL over a list of variables in a dataset, and within the SQL code, I want to use the variables in the list in a WHERE statement to subset the observations by a character value. Specifically, I am looking to count the observations in the dataset where each variable from the list is coded as "Unknown".

I had no problem setting a WHERE MISSING(&VAL)=1 , but I've run into problems when I try to reference a character value.

Here's my code. Since I apparently cannot bold the region that is giving me trouble, I've indicated it with <-- PROBLEM AREA (near the bottom). In addition to providing a solution, any other tips to make my code more efficient would be appreciated.

    %MACRO PERCENTMISSING(LIST);
    PROC SQL NOPRINT;
       %LET N=%SYSFUNC(COUNTW(&LIST));
       %DO I=1 %TO &N;
       %LET VAL = %SCAN(&LIST,&I);
    CREATE TABLE WORK.SALM_&VAL AS
        SELECT DISTINCT "Salmonella" as PATHOGEN,
                            A.YEAR,
                            X.Missing&VAL,
                            Y.Total&VAL,
                            (X.Missing&VAL/Y.Total&VAL) as PropMiss&VAL,
                            C.Unknown&VAL,
                            (C.Unknown&Val/Y.Total&VAL) as PropUnk&VAL
        FROM allsalm as A
        INNER JOIN (
                    SELECT  YEAR,
                            COUNT(*) AS Missing&VAL
                    FROM allsalm
                    WHERE MISSING(&VAL)=1
                    GROUP BY Year) X
        ON A.Year=X.Year
        INNER JOIN (
                    SELECT  YEAR,
                            COUNT(*) AS Total&VAL
                    FROM allsalm
                    GROUP BY Year) Y
        ON A.Year=Y.Year
        INNER JOIN (
                    SELECT  YEAR,
                            COUNT(*) AS Unknown&VAL
                    FROM allsalm
                    WHERE &VAL IN ("Unknown") <-- PROBLEM AREA
                    GROUP BY Year) C
        ON A.Year=C.Year
        ;
    %END;
    QUIT;
    %MEND;

The error message I get is:

ERROR: Column UnknownCity could not be found in the table/view identified with the correlation name C.

Answer 1

Figured it out myself, and added another DO loop to execute PROC SQL for a list of variable across a list of datasets. This might be a nice template for someone attempting to calculate proportions of missing values (and/or "Unknown" values, if your dataset happens to code missing that way as well) for any number of variables across any number of datasets.

   %MACRO PERCENTMISSING(LIST1,LIST2);
   %LET N1=%SYSFUNC(COUNTW(&LIST1));
   %LET N2=%SYSFUNC(COUNTW(&LIST2));
   %DO I=1 %TO &N1;
      %LET VAL1 = %SCAN(&LIST1,&I);
         %DO J=1 %TO &N2;
            %LET VAL2 = %SCAN(&LIST2,&J);

    PROC SQL NOPRINT;
    CREATE TABLE &VAL1&VAL2 AS
        SELECT DISTINCT "&VAL1" as PATHOGEN,
                            A.YEAR,
                            X.Missing&VAL2,
                            Y.Total&VAL2,
                            (X.Missing&VAL2/Y.Total&VAL2) as PropMiss&VAL2,
                            C.Unknown&VAL2,
                            (C.Unknown&VAL2/Y.Total&VAL2) as PropUnk&VAL2
        FROM &VAL1 as A
        LEFT JOIN (
                    SELECT  YEAR,
                            COUNT(*) AS Missing&VAL2
                    FROM &VAL1
                    WHERE (MISSING(&VAL2)=1) OR (&VAL2=" ")
                    GROUP BY Year) X
        ON A.Year=X.Year
        LEFT JOIN (
                    SELECT  YEAR,
                            COUNT(*) AS Total&VAL2
                    FROM &VAL1
                    GROUP BY Year) Y
        ON A.Year=Y.Year
        LEFT JOIN (
                    SELECT  YEAR,
                            COUNT(*) AS Unknown&VAL2
                    FROM &VAL1
                    WHERE &VAL2 IN ("U","Unknown")
                    GROUP BY Year) C
        ON A.Year=C.Year;
    QUIT;
  %END;
%END;
%MEND;

Then just invoke the macro, filling in table names for LIST1 and variable names for LIST2. For example:

%PERCENTMISSING(Table1 Table2 Table3 Table4,Var1 Var2 Var3 Var4 Var5);`