视图问题

Question

Good afternoon. Help to understand please. there is table Purchasing.PurchaseOrderDetail, Purchasing.PurchaseOrderHeader, Production.Product in base AdventureWorks2008R2.

Create a test database in its view, which displays information from these tables as follows:

For each unit OrderQty should be a separate line. If OrderQty = 5, the view will be 5 lines

like this:

OrderQty = 4, ReceivedQty = 3. Result in view:

   ItemNumber      ReceivedInd

       1                1
       2                1
       3                1
       4                0

I tried to use a cursor, but the database does not work. How to write?

declare @in table(i int)
declare @out table (j int)

declare @i int

insert into @in values(7)
insert into @in values(10)
insert into @in values(5)

declare Cur cursor local fast_forward for 
select i from @in

open Cur

fetch next from Cur into @i

while ( @@FETCH_STATUS = 0 )
    begin

    with t as
    (
        select 1 as val
        union all
        select val+1 from t where val<@i
    )
    insert into @out 
    select val from t

    fetch next from Cur into @i
end

close cur
select * from @out

Answer 1

A cursor is not necessary (and not advisable), if you want to repeat a record n number of times, just join to a numbers table, if you don't have one you can easily create a sequence of numbers using:

SELECT ROW_NUMBER() OVER(ORDER BY object_id) FROM sys.all_objects;

So with your simple example you can use:

declare @in table(i int)
insert into @in values(7)
insert into @in values(10)
insert into @in values(5)

SELECT  *
FROM    @in AS i
        CROSS APPLY
        (   SELECT  ROW_NUMBER() OVER(ORDER BY object_id) 
            FROM    sys.all_objects
        ) AS n (Number)
WHERE   i.i >= n.Number
ORDER BY i.i, n.Number;

To make the example slightly more complex:

DECLARE @T TABLE (ID INT IDENTITY(1, 1), OrderQty INT, ReceivedQty INT);
INSERT @T (OrderQty, ReceivedQty) VALUES (4, 3), (5, 2), (2, 2);

SELECT  t.ID,
        ItemNumber = n.Number,
        ReceivedInd = CASE WHEN n.Number > t.ReceivedQty THEN 0 ELSE 1 END
FROM    @T AS t
        CROSS APPLY
        (   SELECT  ROW_NUMBER() OVER(ORDER BY object_id) 
            FROM    sys.all_objects
        ) AS n (Number)
WHERE   t.OrderQty >= n.Number
ORDER BY t.ID, n.Number;

---

The same query works with JOIN, and the execution plan is identical:

DECLARE @T TABLE (ID INT IDENTITY(1, 1), OrderQty INT, ReceivedQty INT);
INSERT @T (OrderQty, ReceivedQty) VALUES (4, 3), (5, 2), (2, 2);

SELECT  t.ID,
        ItemNumber = n.Number,
        ReceivedInd = CASE WHEN n.Number > t.ReceivedQty THEN 0 ELSE 1 END
FROM    @T AS t
        INNER JOIN 
        (   SELECT  Number = ROW_NUMBER() OVER(ORDER BY object_id) 
            FROM    sys.all_objects
        ) AS n
            ON t.OrderQty >= n.Number
ORDER BY t.ID, n.Number;

Answer 2

I think you're just trying to combine the results of GarethD's script with data from additional tables, which is not as hard as you seem to think. Example based on AdventureWorks2008 below:

WITH 
    E1(N) AS (SELECT 1 FROM (VALUES (1),(1),(1),(1),(1),(1),(1),(1),(1),(1))dt(n)), 
    E2(N) AS (SELECT 1 FROM E1 a, E1 b), --10E+2 or 100 rows 
    E4(N) AS (SELECT 1 FROM E2 a, E2 b), --10E+4 or 10,000 rows max 
    cteTally(N) AS ( SELECT ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) FROM E4 ) 

SELECT  
    poh.PurchaseOrderID,
    pod.PurchaseOrderDetailID,
    p.ProductID,
    p.Name,
    p.ProductNumber,
    poh.OrderDate,
    poh.ShipDate,
    n.N AS ItemNumber,
    CASE WHEN n.N > pod.ReceivedQty THEN 0 ELSE 1 END AS ReceivedInd
FROM    
    Purchasing.PurchaseOrderDetail pod
     INNER JOIN 
    Purchasing.PurchaseOrderHeader poh ON 
        pod.PurchaseOrderID = poh.PurchaseOrderID
     INNER JOIN 
    Production.Product p ON 
        pod.ProductID = p.ProductID
     INNER JOIN 
    cteTally n ON 
        pod.OrderQty >= n.N
ORDER BY pod.PurchaseOrderDetailID, n.N;