Perl除非在哈希声明中声明 - 是否可能？

Question

I'm working on a hash table to help iterate over permissions to a file.

I want to flag $permissions{$perm}[0] as 0 if the test is not successful, however I am not sure if this is even possible?

        my %permissions = (
            'w'     => {    'write'         => '0' unless (-w $file) }, #dies here
            'r'     => {    'read'          => '0' unless (-r $file) },
            'x'     => {    'execute'       => '0' unless (-x $file) },
    );

It fails with syntax error near "'0' unless" .

Is there a way to do this inside the hash declaration?

Answer 1

That should be equivalent of what you want

my %permissions = (
        'w'     => { 'write'         => -w $file ? 1 : 0 },
);

or shorter,

        'w'     => { 'write'         => (-w $file) +0 },

Answer 2

Unless there is more to your hash than you have said, it is pointless having two levels of hash as it just means you will have to write $permissions{r}{read} , $permissions{w}{write} etc. I suggest it's best to just use the first level key alone.

In addition, as you will probably be using the hash values as booleans in something like

if ( $permissions{x} ) {
   # Code that runs $file
}

you may as well just store the values returned by the file tests instead of converting them to 1 and 0.

So your hash becomes

my %permissions = (
   w => -w $file,
   r => -r $file,
   x => -x $file,
)

Which will use values of 1 for true and the null string '' for false .

Or you could just assign a hash slice

my %permissions;
@permissions{qw/ r w x /} = (-r, -w, -x) for $file;

which creates the same structure, because the file test operators use the value of $_ if you don't supply a parameter.

Answer 3

Such construct is not permitted, you can use the unless clause only at the end of a statement.

You can use the ternary operator:

my %permissions = (
    'w' => { 'write' => (-w $file ? 'some_value' : 0 ) },
    'r' => { 'read' => (-r $file ? 'some_value' : 0 ) },
    'x' => { 'execute' => (-x $file ? 'some_value' : 0 ) },
)

Answer 4

The correct ways to do this have already been shown here but I thought I'd write a bit about why the example given doesn't work

1. It's nesting hashes when not needed
2. It's a syntax error to use unless with an expression inside a list, hash reference constructor in this case. It only works with normal statements

Here's how the example code could be made valid

my %permissions = (
    w     => do { 0 unless -w $file},
    r     => do { 0 unless -r $file},
    x     => do { 0 unless -x $file});

This works because a do block contains statements but is itself an expression