将变量绑定到节点并在XPath表达式中引用它时出现问题

Question

I have following input:

<?xml version="1.0" encoding="UTF-8"?>
<schema xmlns="http://www.w3.org/2001/XMLSchema"
        xmlns:abc="http://abc.def"
        targetNamespace="http://abc.def"
        elementFormDefault="qualified" 
        attributeFormDefault="unqualified">
  <simpleType name="StatusCategoryId">
    <restriction base="string"/>
  </simpleType>
  <complexType name="StatusCategory">
    <sequence>
      <element name="statusCategoryId" 
               type="abc:StatusCategoryId"/>
      <element name="nameEN" type="string"/>
      <element name="nameCZ" type="string"/>
      <element name="claimCategoryId" type="string"/>
    </sequence>
  </complexType>
  <complexType name="StatusCategoryCollection">
    <sequence>
      <element name="statusCategoryInstance" 
               type="abc:StatusCategory" 
               minOccurs="0"
               maxOccurs="unbounded"/>
    </sequence>
  </complexType>
</schema>

and my desired output is

<?xml version="1.0" encoding="UTF-8"?>
<schema xmlns="http://www.w3.org/2001/XMLSchema" 
        xmlns:abc="http://abc.def"
        targetNamespace="http://abc.def" 
        elementFormDefault="qualified"
        attributeFormDefault="unqualified">
  <simpleType name="StatusCategoryId">
    <restriction base="string"/>
  </simpleType>
  <complexType name="StatusCategory">
    <sequence>
      <element name="statusCategoryId">
        <simpleType name="StatusCategoryId">
          <restriction base="string"/>
        </simpleType>
      </element>
      <element name="nameEN" type="string"/>
      <element name="nameCZ" type="string"/>
      <element name="claimCategoryId" type="string"/>
    </sequence>
  </complexType>
  <complexType name="StatusCategoryCollection">
    <sequence>
      <element name="statusCategoryInstance" 
               minOccurs="0" 
               maxOccurs="unbounded">
        <complexType name="StatusCategory">
          <sequence>
            <element name="statusCategoryId">
              <simpleType name="StatusCategoryId">
                <restriction base="string"/>
              </simpleType>
            </element>
            <element name="nameEN" type="string"/>
            <element name="nameCZ" type="string"/>
            <element name="claimCategoryId" type="string"/>
          </sequence>
        </complexType>
      </element>
    </sequence>
  </complexType>
</schema>

For this purpose I am trying to find the xs:* (anything with W3C schema namespace) that has an attribute @name with the same value as the current element's @type attribute.

However to "flatten" the xs:* element (which can of course be also written as element of some other type defined earlier in the document) I need to get this element into a variable and get through it the same templates as it is being now, recursively. For this purpose I want to call apply-templates select = "$var" . But whenever I try to assign a variable with the element like this, the transformation fails because that variable is not set :(

EDITED xslt begin

    <xsl:variable name="test1">
        <xsl:copy-of select="root(.)//xs:*[@name= $type]"/>
    </xsl:variable>
    <!-- this variables above are here only out of context, 
         not real position in xslt code -->

<xsl:function name="pk:test">
  <xsl:param name="this"/>
  <xsl:variable name="test" select="in-scope-prefixes($this)"/>
  <xsl:element name="namespaces-root">
    <xsl:for-each select="$test">
      <xsl:element name="namespace">
        <xsl:element name="prefix">
          <xsl:value-of select="."/>
        </xsl:element>
        <xsl:element name="ns">
          <xsl:value-of 
            select="namespace-uri-for-prefix(.,$this)"/>
        </xsl:element>
      </xsl:element>
    </xsl:for-each>
  </xsl:element>
</xsl:function>

<xsl:function name="pk:childsHasType">
  <xsl:param name="this"/>
  <xsl:variable name="testX" 
                select="substring-before($this/@type,':')"/>
  <xsl:choose>
    <xsl:when test="$this/*">
      <xsl:for-each select="$this/*">
        <xsl:value-of select="concat(
          $testX != $var/namespace
                    [ns=$defaultSchemaNS]/prefix,
          string-join(pk:childsHasType(.),'|'))"/>
      </xsl:for-each>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of 
        select="$testX != $var/namespace
                          [ns=$defaultSchemaNS]/prefix"/>
    </xsl:otherwise>
  </xsl:choose>

</xsl:function>

<xsl:variable name="var" select="pk:test(./child::*[1])"/>
<xsl:variable name="defaultSchemaNS" 
              select="'http://www.w3.org/2001/XMLSchema'"/>

<xsl:template match="xs:element">
  <xsl:variable name="test0" 
                select="substring-before(@type,':')"/>
  <xsl:variable name="differentTypeTest" 
                select="string-join(pk:childsHasType(.), ', ')"/>
  <xsl:choose>
    <xsl:when test="contains($differentTypeTest,'true')">
      <xsl:variable name="type" select="xs:string" 
                    select="if (contains(@type, ':'))
                            then substring-after(@type,':')
                            else @type"/>
      <xsl:element name="element" 
                   namespace="{$var/namespace[prefix=$test]/ns}">
        <xsl:copy-of select="@*[name()!='type']"/>
        <xsl:text>&#10;</xsl:text>
        <!--next xsl copy to output works flawlessly-->
        <xsl:copy-of select="//node()[./@name = $type]"/>
        <!-- next variable here is unusable :( -->
        <xsl:variable name="test1">
          <xsl:copy-of select="root(.)//xs:*[@name= $type]"/>
        </xsl:variable>
        <xsl:text>&#10;</xsl:text>
        <xsl:apply-templates select="child::node()"/>
        <!--<xsl:copy-of select="child::*"/>-->
      </xsl:element>
    </xsl:when>
    <xsl:otherwise>
      <xsl:copy-of select="."/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

EDITED xslt end

However when I check it with the real string, it works flawlessly...

    <xsl:variable name="test2">
        <xsl:copy-of select="root(.)
                             //xs:*[@name= 'StatusCategoryId']"/>
    </xsl:variable>

I think the cause can be in the setting of the $type variable, however i have tried almost everything and nothing seems to be working, as I could not make an xpath based on variable :(

Answer 1

I couldn't really understand what your XSLT was trying to do, so I approached it purely by comparing the input and output XML.

It looks like you want to look up simpleType and complexType elements by their name, so you can output them elsewhere in your XML. This is probably best achieved using a key

<xsl:key name="complexType" match="xs:simpleType|xs:complexType" use="@name" />

Then it is just a case of matching element elements which refer to one of these types

 <xsl:template match="xs:element[key('complexType', substring-after(@type, ':'))]">

(I am not really sure if you need to check the abc: prefix here too)

Then, to output details of the other type, you can just use the key

<xsl:apply-templates select="key('complexType', substring-after(@type, ':'))" />

Try this XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
                xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">
    <xsl:output method="xml" indent="yes" />

    <xsl:key name="complexType" match="xs:simpleType|xs:complexType" use="@name" />

    <xsl:template match="xs:element[key('complexType', substring-after(@type, ':'))]">
        <xsl:copy>
            <xsl:apply-templates select="@*[local-name() != 'type']"/>
            <xsl:apply-templates select="key('complexType', substring-after(@type, ':'))" />
            <xsl:apply-templates select="node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Answer 2

There are a number of problems with what you are doing, if we assume that we understand the task and the target vocabulary (XSD). For example, your expected output is not a valid schema because a local simpleType or complexType must not have a name attribute; also the problems CMSp-McQ mentions: though this may not be a problem if you know that your input is using a limited subset of what XSD allows.

However, treating this purely as a transformation of an arbitrary XML document, I'm having trouble seeing exactly what the problem is. You say "the transformation fails on that variable is not set", but that doesn't sound like a Saxon error message, it sounds like your paraphrase of an error message. You say that the variable test1 is unusable, but you don't show any code that is attempting to use it. It would be much easier to help you if you tell us exactly what you are doing and exactly what is going wrong, and preferably give us a complete (but minimal) source document and stylesheet so we can try it for ourselves.

For the SO thought-police, I know this isn't an answer but it's too long to go in a comment.