VBA中的Excel宏-如何应用循环向下移动列

Question

I have a sub Macro that basically works as a currency converter that allows the user to define their own exchange rate values. I have tested it on one cell and works fine but I need it to loop and move down a row for a define range. (Currently the cells defined are L2, K2 and G", need to to repeat on L3, K3 and G3 until Ln, Kn and Gn etc.)

Code is as follows:

Sub Macro9()
'
' Macro9 Macro
'

Dim score As String, result As String
score = Sheets("Paste Orders Here").Range("K2").Value

If score = "USD" Then
    result = Sheets("Paste Orders Here").Range("L2") * Sheets("Configuration").Range("C5")
ElseIf score = "EUR" Then
    result = Sheets("Paste Orders Here").Range("L2") * Sheets("Configuration").Range("B5")
ElseIf score = "GBP" Then
    result = Sheets("Paste Orders Here").Range("L2")
ElseIf score = "" Then
    result = Sheets("Paste Orders Here").Range("K2")
End If

Sheets("Brightpearl").Range("G2").Value = result
'
End Sub

Thanks, I understand this could be completely incorrect for wanting to apply this to multiple rows but I could really use some help!

Answer 1

Here is my interpretation. I wasn't quite sure how far to fill the formulas down as you only referred to this as n so I used the bottom of Paste Orders Here 's column L.

Sub Macro9()
    Dim r As Long, lr As Long
    With Sheets("Paste Orders Here")
        lr = .Cells(.Rows.Count, "K").End(xlUp).Row
        For r = 2 To lr
            Select Case UCase(.Cells(r, "K").Value)
                Case "USD"
                    Sheets("Brightpearl").Cells(r, "G") = _
                      CCur(.Cells(r, "L").Value * Sheets("Configuration").Range("C5").Value)
                Case "EUR"
                    Sheets("Brightpearl").Cells(r, "G") = _
                      CCur(.Cells(r, "L").Value * Sheets("Configuration").Range("B5").Value)
                Case "GBP"
                    Sheets("Brightpearl").Cells(r, "G") = CCur(.Cells(r, "L").Value)
                Case Else
                    Sheets("Brightpearl").Cells(r, "G") = .Cells(r, "K").Value
            End Select
        Next r
    End With
End Sub

I find a Select Case method works well in these cases and provides ease of future expandability.