批处理文件不会回显到文件中

Question

why do these lines not work?

echo   POSITION-X: %shopxpos%>>shop%shopid%.yml
echo   POSITION-Y: %shopypos%>>shop%shopid%.yml
if "%shopincludedata%" == "y" (echo   DATA-VALUE: %shopitemdata%>>shop%shopid%.yml) else if "%shopincludedata%" == "Y" (echo   DATA-VALUE: %shopitemdata%>>shop%shopid%.yml) else if "%shopincludedata%" == "yes" (echo   DATA-VALUE: %shopitemdata%>>shop%shopid%.yml) else if "%shopincludedata%" == "YES" (echo   DATA-VALUE: %shopitemdata%>>shop%shopid%.yml) else if "%shopincludedata%" == "Yes" (echo   DATA-VALUE: %shopitemdata%>>shop%shopid%.yml)

they just don't spit out into the file here's the file i'm using this in: https://www.dropbox.com/s/xui34kgkdjmee3p/ChestCommands.bat?dl=0

Answer 1

The problem is the values of %shopxpos% and %shopypos% are single digit numbers, and single digit numbers are used to identify which file handles should be redirected. You want the number to be treated as a literal string value to be ECHOed, but the parser is treating the number as a file handle identifier instead.

The simplest solution is to move the redirection to the front of the command. It can appear anywhere.

I would not check for all those variations of "yes". Instead, I would check to see if the first character is Y , case insensitive.

>>shop%shopid%.yml echo   POSITION-X: %shopxpos%
>>shop%shopid%.yml echo   POSITION-Y: %shopypos%
if /i "%shopincludedata:~0,1%" == "y" >>shop%shopid%.yml echo   DATA-VALUE: %shopitemdata%

or better yet, use parentheses and redirect only once.

>>shop%shopid%.yml (
  echo   POSITION-X: %shopxpos%
  echo   POSITION-Y: %shopypos%
  if /i "%shopincludedata:~0,1%" == "y" echo   DATA-VALUE: %shopitemdata%
)