如何找到Perl多级哈希中的哪些键对应于给定值？

Question

I have a data structure which looks like this:

my %hoh = (
    'T431567' => {
        machin => '01',
        bidule => '02',
        truc   => '03',
    },
    'T123456' => {
        machin => '97',
        bidule => '99',
        truc   => '69',
    },
    'T444444' => {
        machin => '12',
        bidule => '64',
        truc   => '78',
    },
);

I want to search the various values of truc for a particular value and find the top-level attribute which corresponds to that entry. For example, looking for a value of 78 , I want to find the result 'T444444' , because $hoh{T444444}{truc} is 78 .

How can I do this, please?

Answer 1

You can do this with grep :

my @keys = grep { $hoh{$_}{truc} == 78 } keys %hoh;

Note that this can return more than one key, if there are duplicate values in the hash. Also note that this is not particularly efficient, since it has to search the entire hash. In most cases it's probably fine, but if the hash can be very large and you may need to run lots of such queries against it, it may be more efficient to build a reverse index as suggested by Sobrique:

my %trucs;
foreach my $part (keys %hoh) {
    my $val = $hoh{$part}{truc};
    push @{ $trucs{$val} }, $part;
}
my @keys = @{ $trucs{78} };

or, more generally:

my %index;
foreach my $part (keys %hoh) {
    my %data = %{ $hoh{$part} };
    foreach my $key (keys %data) {
        my $val = $data{$key};
        push @{ $index{$key}{$val} }, $part;
    }
}
my @keys = @{ $index{truc}{78} };

Answer 2

Can't with that data structure as is - There is no 'backwards' relationship from value to key without you creating it.

You've two options - run a search, or create an 'index'. Practically speaking, these are the same, just one saves the results.

my %index;
foreach my $key ( keys %hoh ) {
    my $truc = $hoh{$key}{'truc'};
    $index{$truc} = $key; 
}

Note - won't do anything clever if the 'truc' numbers are duplicated - it'll overwrite. (Handling this is left as an exercise to the reader).

Answer 3

This solution is similar to those already posted, but it uses the each operator to process the original hash in fewer lines of code, and probably more quickly.

I have added the dump output only so that you can see the form of the structure that is built.

use strict;
use warnings;

my %hoh = (
  T123456 => { bidule => '99',  machin => '97',  truc => '69' },
  T431567 => { bidule => '02',  machin => '01',  truc => '03' },
  T444444 => { bidule => '64',  machin => '12',  truc => '78' },
);

my %trucs;

while ( my ($key, $val) = each %hoh ) {
  next unless defined( my $truc = $val->{truc} );
  push @{ $trucs{$truc} }, $key ;
}

use Data::Dump;
dd \%trucs;
print "\n";

print "$_\n" for @{ $trucs{78} };

output

{ "03" => ["T431567"], "69" => ["T123456"], "78" => ["T444444"] }

T444444

If you can guarantee that the answer is unique, ie that there is never more than one element of the original hash that has a given value for the truc entry, or you are interested only in the last one found, then you can write this still more neatly

my %trucs;

while ( my ($key, $val) = each %hoh ) {
  next unless defined( my $truc = $val->{truc} );
  $trucs{$truc} = $key ;
}

print $trucs{78}, "\n";

output

T444444

Simplest of all, if there is always a truc entry in each second-level hash, and its values is guaranteed to be unique, then this will do the job

my %trucs = map { $hoh{$_}{truc} => $_ } keys %hoh;

print $trucs{78}, "\n";

with the output as above.