Perl：对于循环退出条件（最后）未按预期工作

Question

so I'm having an issue with my second for loop below.

The first for loop finds the first instance of ATG in the ARRAY.

The second for loop is supposed to report the first instance of TAA, TAG, or TGA in the ARRAY that is after the first ATG. But instead it reports the position of the last TAA, TAG, or TGA in the ARRAY. I'm not sure why my condition for exiting the loop is not preventing this nor how to fix it.

Any tips would be appreciated.

my @test_srsrspsp = ( "CCC", "ATG", "ATG", "CGC", "TAA", "TAG" );

sub orf_length {
    #index scalars
    my $rf0_start;
    my $rf0_end;
    #index value counter
    my $i = 0;
    #finds first appearance of ATG in array
    for (@_) {
        $rf0_start = $i if $_ eq 'ATG';
        last if ( defined $rf0_start );
        $i++;
    }
    #only looks for TAG, TAA, or TGA if ATG was found first
    if ( defined $rf0_start ) {
        #reset counter
        $i = 0;
        #is supposed to return the index value of the first appearance of TAG, TAA, or TGA
        #that has an index value larger than that of ATGs but instead returns the index value
        #of the last TAA, TAG, or TGA
        for (@_) {
            $rf0_end = $i if $_ =~ /TA(G|A)|TGA/;
            if ( ( defined $rf0_end ) > $rf0_start ) {
                last;
            }
            $i++;
        }
    }
    #reports positions of found values and the number length of the sequence between them
    if ( defined( $rf0_end and $rf0_start ) ) {
        my $length = ( $rf0_end - $rf0_start + 1 ) * 3;
        print "Start Codon after pos: $rf0_start \n";
        print "End Codon at pos: $rf0_end \n";
        print "First ORF of \n@_ \nhas length: $length \n";
    } else {
        print "No ORF found in @_\n";
    }

}

I've also tried using a different version of the for loop with no success.

for (@_) {
    $rf0_end = $i if $_ =~ /TA(G|A)|TGA/;
    last if ( ( defined $rf0_end ) > $rf0_start );
    $i++;
}

Answer 1

Issue is if ( ( defined $rf0_end ) > $rf0_start ) in the second loop. It compares a boolean with integer value. To work properly it can be replaced with

Working syntax: if ( ( defined $rf0_end ) && ($rf0_end > $rf0_start) )

Answer 2

You also have a problem with the line

if ( defined( $rf0_end and $rf0_start ) ) {

which needs to be

if ( defined $rf0_end and defined $rf0_start ) {

although, in this case,

if ( defined $rf0_end ) {

will do fine, as $rf0_end gets defined only if $rf0_start is defined.

I would prefer to use the firstidx function from List::MoreUtils to do this, as shown below, although you may need to install the module as it isn't in core at present.

use strict;
use warnings;

use List::MoreUtils 'firstidx';

my @test_srsrspsp = qw/ CCC ATG ATG CGC TAA TAG /;

orf_length(@test_srsrspsp);

sub orf_length {

    my ($rf0_start, $rf0_end, $rf0_len);

    $rf0_start = firstidx { /ATG/ } @_;
    if (defined $rf0_start) {
        my $offset = $rf0_start + 1;
        $rf0_end = $offset + firstidx { /TA[GA]|TGA/ } @_[$offset .. $#_];
    }

    if (defined $rf0_end) {
        my $rf0_len = ($rf0_end - $rf0_start + 1) * 3;
        print "Start Codon after pos: $rf0_start \n";
        print "End Codon at pos: $rf0_end \n";
        print "First ORF of\n@_\nhas length: $rf0_len\n";
    }
    else {
        print "No ORF found in @_\n";
    }
}

output

Start Codon after pos: 1 
End Codon at pos: 4 
First ORF of 
CCC ATG ATG CGC TAA TAG 
has length: 12 

Update

If you prefer to avoid the module, you could write it this way. The functionality is identical.

sub orf_length {

   my ($rf0_start, $rf0_end, $rf0_len);

    my $i = 0;
    for (@_) {
        if (not defined $rf0_start) {
            $rf0_start = $i if /ATG/;
        }
        elsif (/TA[GA]|TGA/) {
            $rf0_end = $i;
            last;
        }
        ++$i;
    }

    if (defined $rf0_end) {
        my $rf0_len = ($rf0_end - $rf0_start + 1) * 3;
        print "Start Codon after pos: $rf0_start \n";
        print "End Codon at pos: $rf0_end \n";
        print "First ORF of\n@_\nhas length: $rf0_len\n";
    }
    else {
        print "No ORF found in @_\n";
    }
}