如何将getitemdata转换并将itemdata从vb6组合设置为vb.net组合方法

Question

hi we are migrating vb6 to vb.net .In vb 6 combobox methods are not supported in vb.net

VB6.GetItemString(cboEditBox(0), cboEditBox(0).SelectedIndex)
VB6.Format(VB6.GetItemData(cboEditBox(0), cboEditBox(0).SelectedIndex)
VB6.Format(frmTableRate.txtRate.Text, "##0.0####")
VB6.SetItemData(cboEditBox(0), cboEditBox(0).SelectedIndex
CheckUsage(sSQLWhere, VB6.Format(frmTableRate.Tag), sMsg, bUsed) 
VB.Left(VB6.GetItemString(lstRates, lstRates.SelectedIndex)
sTableID = VB6.Format(VB6.GetItemData(cboEditBox(0), cboEditBox(0).SelectedIndex), "000")

Answer 1

Here's a simple sample of how combo box items in VB.NET could easily store display values and data values. To try it, just paste this code on an empty form called Form1. It will create the control and hook up event handlers by itself.

Public Class ComboItem
   Public Property DisplayString As String
   Public Property ItemData As Object
   Public Sub New(DisplayString As String, Optional ItemData As Object = Nothing)
      Me.DisplayString = DisplayString
      Me.ItemData = ItemData
   End Sub
End Class

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
   Dim cboEditBox As New ComboBox
   Controls.Add(cboEditBox)
   Dim comboData As New System.ComponentModel.BindingList(Of ComboItem)
   cboEditBox.DataSource = comboData
   cboEditBox.DisplayMember = "DisplayString"
   cboEditBox.ValueMember = "ItemData"

   comboData.Add(New ComboItem("One"))
   ' Demonstrate setting item data along with creation of the list items
   comboData.Add(New ComboItem("Two", "First duplicate"))
   comboData.Add(New ComboItem("Two", "Second duplicate"))

   ' Demonstrate SetItemData alternative
   DirectCast(cboEditBox.SelectedItem, ComboItem).ItemData = "The first item"
   AddHandler cboEditBox.SelectedIndexChanged, AddressOf cboEditBox_SelectedIndexChanged
End Sub

Private Sub cboEditBox_SelectedIndexChanged(sender As Object, e As EventArgs)
   Dim target As ComboBox = DirectCast(sender, ComboBox)
   ' Demonstrate GetItemData alternative
   MsgBox(target.SelectedValue)
End Sub

Note, by using BindingList (instead of an array or regular List), we ensure that even after the ComboBox is initialized, adding or removing elements from the list directly will be reflected in the combo box without having to refresh the combo box DataSource property. If you want to manually refresh the combo box DataSource property manually, a simple array or list could be used instead.