如何自动创建名称为当天的文件夹并将现有文件和子文件夹移动到该文件夹​​中？

Question

I need a simple tool to do my repeating job. So I wrote some commands in text file and saved the file as *.bat file.

1. Create a new folder with current day in month as folder name.

   Example: Today is 13-11-14 (format date: dd-mm-yy)

   MD=%date:~0.2%

   Created folder: 13

2. Move existing files or folders into folder 13 .

   Example:

   Before batch file execution the current folder contains:

   • Folder a
   • Folder b
   • File c
   • File d

   After batch file execution the current folder should contain:

   • 17
     • Folder a
     • Folder b
     • File c
     • File d

I drew an image to show what I need.

I don't know how to write that second part of the task.

Which commands are needed to move all files and subfolders in current folder to a new folder with name of current day in month?

Answer 1

Okay, here is the small batch file for this task with comments and an extra check.

@echo off
rem Get name of batch file in case of being in current directory, too. It is
rem verified if the batch file executed is really in the current directory.
set "BatchFileName="
if "%~dp0"=="%CD%\" set "BatchFileName=%~nx0"

rem Get current day of month. Works only with date formats beginning with day.
set "Day=%DATE:~0,2%"

rem Create the directory if it does not already exist.
if not exist "%Day%" mkdir "%Day%"

rem Move all subdirectories except the directory of current day.
for /D %%D in (*) do if not "%%D"=="%Day%" move /Y "%%D" "%Day%"

rem Move all files except running batch file.
for %%F in (*) do if not "%%F"=="%BatchFileName%" move /Y "%%F" "%Day%"

rem Delete the two environment variables used for this task.
set "BatchFileName="
set "Day="

The help of the used commands can be read in a command prompt window after entering:

• help if or if /?
• help for or for /?
• help set or set /?
• help move or move /?
• help mkdir or help md or mkdir /? or md /?

Answer 2

It's working great, thanks Mofi, but not perfect :D for me.

I try but can't write more step. Can you edit a little bit?

1. Delete all empty folders

2. Move EXACTLY folders what I need to move (a, b, c):

I have exactly 7 folders to move.

Before batch file execution the current folder contains:

• Folder a
• Folder b
• Folder c
• Folder MONTH 11
• Folder d
• File e
• ....

After batch file execution the current folder should contain:

If folder L1 already exist, create new as folder name L2, L3, L4, ...

• Folder 17
  • Folder L1
    • Folder a
    • Folder b
    • Folder c
• Folder MONTH 11
• Folder d
• File e
• ....

3. Move folder "17" into folder has name "MONTH 11":

Before batch file execution the current folder contains:

• Folder 17
  • Folder L1
    • Folder a
    • Folder b
    • Folder c
• Folder MONTH 11
• Folder d
• File e
• ....

After batch file execution the current folder should contain:

• Folder MONTH 11
  • folder 17
    • Folder L1
      • Folder a
      • Folder b
      • Folder c
• Folder d
• File e
• ....

---

Edit by Mofi

For the next time, never ask something new in an answer of a question. Create instead a new question with a reference (link) to the former, similar question. This gives you and other users the possibility to earn more reputation.

I post here below the batch file code for your new requirements although it is not possible for you to accept my answer now.

@echo off
rem Delete empty folders. Command rmdir does not delete a folder without
rem parameter /S if it contains a file or a subfolder. The error message
rem output if folder is not empty is redirected to NUL device to suppress it.
rmdir "Folder a" 2>nul
rmdir "Folder b" 2>nul
rmdir "Folder c" 2>nul

rem Get directory for current day in current month.
set "DayFolder=MONTH %DATE:~3,2%\%DATE:~0,2%"

rem Create the day folder and if necessary automatically also the month folder.
if not exist "%DayFolder%" mkdir "%DayFolder%"

rem Check existence of L* subfolders in day folder.
set "Number=1"
:Loop
if exist "%DayFolder%\L%Number%" set /A "Number+=1" & goto Loop

rem Create the next L* subfolder in day folder.
mkdir "%DayFolder%\L%Number%"

rem Move the remaining folders into new L* subfolder in day folder.
if exist "Folder a" move /Y "Folder a" "%DayFolder%\L%Number%"
if exist "Folder b" move /Y "Folder b" "%DayFolder%\L%Number%"
if exist "Folder c" move /Y "Folder c" "%DayFolder%\L%Number%"

rem Delete the last L* day folder if it does not contain anything.
rmdir "%DayFolder%\L%Number%" 2>nul

rem Delete the current day folder in current month if still empty.
rmdir "%DayFolder%" 2>nul

rem Delete the current month folder if still empty.
rmdir "MONTH %DATE:~3,2%" 2>nul