awk中“ in”函数的含义

Question

I don't really understand the phrase in in awk code, ie

awk -F'|' 'NR>1{
      band[$2]++
  }
  END{
    print "Band | Sum"
      for (x in band){
        print x" | " band[x]
      }
  }'

and

awk -F"|" 'NR==FNR{a[$1]=$2;next}{for(i=3;i<=NF;i++){if($i in a)sub($i,a[$i],$i)}print}' OFS="|" lookupfile contentfile

what does it do if the phrase is if($x in array) and for(x in array) ?

Answer 1

From man awk :

The special operator in may be used to test if an array has an index consisting of a particular value:

if (val in array)
   print array[val]

If the array has multiple subscripts, use (i, j) in array.

The in construct may also be used in a for loop to iterate over all elements of an array.

---

So your script:

awk -F'|' 'NR>1{
      band[$2]++
  }
  END{
    print "Band | Sum"
      for (x in band){
        print x" | " band[x]
      }
  }'

Does the following:

• band[$2]++ Creates an array band in which you store a counter of how many times each 2nd field appears.
• for (x in band) loop through the elements in the array band to do some stuff with them. Note the for (x in band) allows you to do something with the element x as index and band[x] as value.

Answer 2

its just like any other language within a for loop. The "in" just means you have a counter and it will go through each element within "band"

so when you print band[x] it is like saying print the element IN band where ever the counter is.

Answer 3

in means two different things in those case. First:

if($i in a)sub($i,a[$i],$i)}print

In this form, $i in a is a logical test. It returns true if $i is one of the keys of array a and returns false otherwise.

Second:

for (x in band){
        print x" | " band[x]
      }

In this form, the statement print x" | " band[x] is run once for x assigned to each of the keys of the array a .

Examples

Consider a file with the contents:

abc
def
hij

Now, let's run an awk command with the for (x in a) construct:

$ awk '{a[$1]=NR} END{for (x in a) print "a[" x "]="a[x]}' file
a[def]=2
a[hij]=3
a[abc]=1

The first part, a[$1]=NR creates an array a whose keys are the first word on the line, $1 , and whose values are the number of the record (line) on which the word occurred, NR .

The for loop goes over every key of the array. It does not go through them, though, in any particular order.

Now, let's add one if condition to the above code. We will use if ("klm" in a) {...} :

$ awk '{a[$1]=NR} END{if ("klm" in a) {for (x in a) print "a[" x "]="a[x]}}' file

The above produces no output. This is because array a has not such key as klm .

If, instead, we had written if ("abc" in a) {...} , then there would be output:

$ awk '{a[$1]=NR} END{if ("abc" in a) {for (x in a) print "a[" x "]="a[x]}}' file
a[def]=2
a[hij]=3
a[abc]=1

Answer 4

Fortunately there's a book that explains it all, Effective Awk Programming, Third Edition, by Arnold Robbins. You'll be interested in these sections of it:

http://www.gnu.org/software/gawk/manual/gawk.html#Reference-to-Elements

http://www.gnu.org/software/gawk/manual/gawk.html#Scanning-an-Array