如何创建动态SQL查询

Question

I have int[] ids and i want to create an sql statement where i have to get all the details of theuser where user_id in (int[]).I am using prepared statement , so please help me with this.

SELECT * FROM userrequest WHERE USER_ID IN ?

Now the problem is what to set in the parameter.There is nothing as pstmt.setintarray.

Answer 1

One solution ( of not using dynamic sql , Assuming you're using MSSQL SERVER) :

Assuming you send a CSV string of values :

'1,2,3,4'

You can do :

SELECT * FROM userrequest WHERE USER_ID IN (SELECT Element  from dbo.FN_Split('1,2,3,4',','))

Where FN_Split is :

CREATE FUNCTION [dbo].[FN_Split] 
(
    @InDelimitedString varchar(max),
    @InDelimiter       varchar(10) 
)
RETURNS 
    @tblArray TABLE 
    (
        ElementID  smallint IDENTITY(1,1), 
        Element    varchar(1000)
    )

AS
BEGIN

    DECLARE @StrPos smallint,
    @StrStart smallint,
    @DelimiterLength smallint

    SET @DelimiterLength = LEN(@InDelimiter)    

    --loop through source string and add elements to destination table array
    WHILE LEN(@InDelimitedString) > 0
        BEGIN
            SET @StrPos = CHARINDEX (@InDelimiter, @InDelimitedString)
            IF @StrPos = 0
                BEGIN
                    INSERT INTO @tblArray VALUES(@InDelimitedString)
                    BREAK
                END
            ELSE
                BEGIN
                    INSERT INTO @tblArray VALUES(SUBSTRING(@InDelimitedString, 1,@StrPos - 1))
                    SET @StrStart = @StrPos + @DelimiterLength
                    -- Shift source string left
                    SET @InDelimitedString = SUBSTRING(@InDelimitedString, @StrStart , LEN(@InDelimitedString) - @StrStart + 1)
                END
        END

    RETURN 
END