了解Perl数组中的引用以及如何访问数据

Question

I could do with some help on perl and how it handles its arrays. (A long time ago) I used to do quite a lot of coding (hacking would be a better description, never pretty work) using php, java, js, etc but for various reasons I'm using perl for a project and i'm struggling to work out why I'm finding arrays such a pain.

For example, the following code:

@inflightsequences=([1,6,[["SRCIP","1.2.3.4"],["DSTIP","5.6.7.8"]]],[2,2,[["SRCIP","1.2.3.4"],["DSTIP","5.6.7.8"]]]);

foreach (@inflightsequences) {print Dumper @_};

where the definition of the array creates this (printed using Dumper)

$VAR1 = [
      1,
      6,
      [
        [
          'SRCIP',
          '1.2.3.4'
        ],
        [
          'DSTIP',
          '5.6.7.8'
        ]
      ]
    ];

$VAR2 = [
      2,
      2,
      [
        [
          'SRCIP',
          '1.2.3.4'
        ],
        [
          'DSTIP',
          '5.6.7.8'
        ]
      ]
    ];

(NB I'll refer to the data inside the array using VAR1 and VAR2 from now on so its clear which block I'm referring to, regardless of whether thats actually what Dumper calls it)

...but the foreach outputs absolutely nothing, when I expected it to cycle twice and output whats in VAR1 first then in VAR2. However

print Dumper @inflightsequences[0];
print Dumper @inflightsequences[1];

does print out VAR1 and VAR2 as expected.

Then I extract the first item from the @inflightsequences array

@dataset = shift(@inflightsequences);

and I expected print $dataset[1] to print out the first value (1) in what was VAR1 and print $dataset[2] to print the second value (6) but no, to achieve what I expected I have to do print $dataset[0][0] and print $dataset[0][1] . Why the extra [0]?

And thus I have got myself completely confused....

Thanks

--Chris

Answer 1

@inflightsequences is an array of array references so

$r=shift(@inflightsequences)

print $r->[0]

will show 1

and

print $r->[1]

will show 6

doing

@dataset=shift(@inflightsequences)

Makes an array from the result from the shift. So it's a array with one element, the shift result, which is accessed as $dataset[0]. $dataset[0]->[1] will give 6, for example

Answer 2

What is confusing you is that the elements of Perl arrays are always scalar values. You make arrays of arrays by using references for those scalars.

You can create an array reference either by building a named array and taking its reference

my @data = ( 'a', 'b', 'c' );
my $array_ref = \@data;

or by creating an anonymous array

my $array_ref = [ 'a', 'b', 'c' ];

The only difference between these two is that the data can be accessed through the name @data in the first case as well as through the reference $array_ref . To access elements of an array through a reference, you use the arrow operator, so

$array_ref->[0]

is the same as

$data[0]

The reason your foreach loop prints nothing is that you are dumping the contents of the array @_ which you have never mentioned before and is empty. @_ is the array that is set within a subroutine to the actual parameters passed when that subroutine is called. It has no use otherwise.

Remembering that array elements are scalars , and that if you don't specify a loop control variable then Perl will use $_ , what you should have written is

foreach (@inflightsequences) { print Dumper($_) }

or, more Perlishly,

print Dumper($_) for @inflightsequences

The same applies to your statement

@dataset = shift(@inflightsequences)

which, again, because the contents of @inflightsequences are scalars is removing the first array reference and putting it into @dataset , which is now just a one-element array containing an array reference. That means you have moved $inflightsequences[0] to $dataset[0] , which is now equal to

[1, 6, [ ["SRCIP", "1.2.3.4"], ["DSTIP", "5.6.7.8"] ] ]

not forgetting that the square brackets create a reference to an anonymous array. So, like our $array_ref->[0] above, you can access the first element of this array using $dataset[0]->[0] . And because Perl allows you to remove the arrow operator between pairs of square brackets (and curly brackets if we're using hashes) you can contract that to $dataset[0][0] which happens to be the value 1.

I hope that helps. You would do well to read perlref and experiment a little. Note that the Data::Dump module produces output much superior to Data::Dumper , but you may need to install it as it isn't a core module. Once it's installed the code will look like

use Data::Dump;

dd \@inflightsequences;