批量拆分和比较字符串

Question

I essentially need to take this output from a netdom query fsmo:

Schema Master           server1.domain.local
Domain Naming Master    server1.domain.local
PDC                     server1.domain.local
RID Pool Manager        server1.domain.local
Infrastructure Master   server1.domain.local

And check that the server I am running my script against, is in fact the PDC holder. So essentially the logic would be:

• Get current hostname and store in variable netdom query fsmo | find "PDC" netdom query fsmo | find "PDC" and store in variable
• Compare the actual hostname against the hostname in the query variable above
• IF true do this, IF false do that.

I'm really not that familiar with batch (more of a PowerShell guy) and was wondering if there is an easy way to achieve this in batch?

Answer 1

This should get you started. It assumes that netdom query fsmo is the exact command you run and produces the output exactly as noted in your question.

@ECHO OFF
SETLOCAL

REM Look for PDC entry. If it is found, take the last text value.
REM Note that FINDSTR is case sensitive without the /I switch.
FOR /F "usebackq tokens=1,2 delims= " %%A IN (`netdom query fsmo ^| FINDSTR /B PDC`) DO SET PdcServer=%%B

REM See if we found it.
IF "%PdcServer%"=="" GOTO :EOF 

REM If we get here, there is an entry.
ECHO PDC Server is %PdcServer%

REM Compare to the current server.
SET CurrentServer=%ComputerName%.%UserDnsDomain%
ECHO This Server name is %CurrentServer%

IF "%PdcServer%"=="%CurrentServer%" (
    REM This is the PDC server. Do Something.
) ELSE (
    REM Not the PDC server.
)

ENDLOCAL

Answer 2

In theory,

for /f "tokens=1,2" %%a in ('netdom query fsmo') do if "%%a"=="PDC" if "%%b"=="actualhostname" (dothis) else (dothat)

If you are running directly from the prompt, reduce all %% to % .