Qt：与Qt OSX优胜美地的CUDA“sed：非法选项 - r”错误

Question

I am building a simple app with Qt creator, in which I want to utilise CPU and GPU computation to complete a task and then compare the execution time in m/s.

I have read numerous articles and have concluded that I need to separate NVCC and GCC compilers from one another to avoid conflict. I followed this tutorial , making tweaks for my system, however when I compile I get a strange error:

sed: illegal option -- r
usage: sed script [-Ealn] [-i extension] [file ...]
       sed [-Ealn] [-i extension] [-e script] ... [-f script_file] ... [file ...]
make: *** [gaussian_cuda.o] Error 1
14:42:46: The process "/usr/bin/make" exited with code 2.

The error is obviously being thrown from this line in my .pro configuration:

2>&1 | sed -r \"s/\\(([0-9]+)\\)/:\\1/g\" 1>&2

I don't understand why this is an illegal operation, and when I try to remove this line my code breaks completely.

Why is r an illegal operation?

EDIT Complete config code:

QT       += core gui
QT       += multimedia
QT       += multimediawidgets
QT       += concurrent

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TARGET = WebcamFilter
TEMPLATE = app

SOURCES += main.cpp\
           mainwindow.cpp \
           camerafeed.cpp \

HEADERS  += mainwindow.h \
            camerafeed.h

FORMS    += mainwindow.ui

# CUDA Resources
CUDA_SOURCES += gaussian.cu
CUDA_DIR      = /usr/local/cuda
# Path to header and lib files
INCLUDEPATH  += $$CUDA_DIR/include
QMAKE_LIBDIR += $$CUDA_DIR/lib
# Libs used for source code
LIBS         += -lcudart -lcuda
# GPU Architecture
CUDA_ARCH     = sm_20
# Custom flags for nvcc
NVCCFLAGS     = --compiler-options -fno-strict-aliasing -use_fast_math --ptxas-options=-v
# Prepare extra compiler configuration
CUDA_INC      = $$join(INCLUDEPATH,' -I','-I',' ')
cuda.commands = $$CUDA_DIR/bin/nvcc -m64 -O3 -arch=$$CUDA_ARCH -c $$NVCCFLAGS \
                $$CUDA_INC $$LIBS  ${QMAKE_FILE_NAME} -o ${QMAKE_FILE_OUT} \
                2>&1 | sed -r \"s/\\(([0-9]+)\\)/:\\1/g\" 1>&2
cuda.dependency_type = TYPE_C
cuda.depend_command  = $$CUDA_DIR/bin/nvcc -O3 -M $$CUDA_INC $$NVCCFLAGS   ${QMAKE_FILE_NAME}

cuda.input = CUDA_SOURCES
cuda.output = ${OBJECTS_DIR}${QMAKE_FILE_BASE}_cuda.o
# Tell Qt that we want add more stuff to the Makefile
QMAKE_EXTRA_COMPILERS += cuda

Answer 1

As Park Young-Bae suggested, Mac sed is not equivalent to GNU sed and therefore the flag:

2>&1 | sed -r \"s/\\(([0-9]+)\\)/:\\1/g\" 1>&2

had to be amended to:

2>&1 | sed -E \"s/\\(([0-9]+)\\)/:\\1/g\" 1>&2

This fixed the issue.