Excel VBA验证对象

Question

A VBA feature that I haven't use and need advice on.

I have a large, hideous sheet that needs data validation upon data entry. Lots of typos and bad numbers to fix. I just started playing with the Validation object and need advice...

• I'm a little wary of using the interface-based Data Validation, especially from a maintenance perspective. Is that silly?

• Are Ranges (or anything else) allowed to have more than one validation object?

• Is there a simple way to trigger the validation object upon cell entry, or is that just the same as using the interface-based Validation?

• Am I making a big deal out of nothing?

Thanks, Mike

Answer 1

Taking your questions in order 1. Using the inbuilt Data validation is the easiest and simplest method to go with but it does have limitations. You are not being silly, but the answer depends on your situation, taking several factors into account such as "how often do you anticipate the validations might change", "how complex are the validations", "how many different users might be using this sheet"? (I find the more users you have, the more likely one of them will do something different and "break" your validations. The biggest issue I have encountered with in cell Data validation is that is is susceptible to users copying cells and pasting over the top of your validations and this removes the validation (without the user or you realising it) 2. As far as I know, you cannot have more than 1 data validation per cell 3. I no longer use the below method, and came up with my own custom data validation method, but the code below effectively reruns the in-cell Data validation checks. This procedure is called for our wider Validatiosn module, which is run at the end of data entry, so it isn't run in "real time"

Sub copy_paste_errors_CO()

If Application.Version >= "12.0" Then
Application.StatusBar = "Checking for Cell Format errors"
' This will work for excel 2007 but not earlier
'--------- Identify Copy and Paste errors where cell level validation not activated
    Dim DataRange As Range
    Dim c As Range
    Dim count As Long
    Dim ExactMatch As Boolean
    'Find the cells containing Data Validation
    Set DataRange = Worksheets("Contacts").Range(CO_DataRange).SpecialCells(xlCellTypeAllValidation)
    If DataRange Is Nothing Then
        MsgBox "no cells with any validation"
    Else
        'Loop through each cell that has data validation
        For Each c In DataRange
            If Not IsError(c.Value) Then 'If the data validation errors
                If Len(c.Value) > 0 Then ' only check if data in cell '
                    ExactMatch = False
                    If c.Validation.Type <> xlValidateList Then
                        If c.Validation.Value Then
                            ExactMatch = True
                        End If
                    Else   'List validation
                        Dim LookupName, MatchValue As String
                        Dim rng As Range
                        LookupName = c.Validation.Formula1
                        LookupName = Right(LookupName, Len(LookupName) - 1)
                        Set rng = Range(LookupName).Find(c.Value, LookIn:=xlValues, lookat:=xlWhole)
                        If Not rng Is Nothing Then
                            If StrComp(rng, c.Value, vbBinaryCompare) = 0 Then
                                ExactMatch = True
                            End If
                        End If
                    End If
                    If Not ExactMatch Then
                        'If there is an error, store the error in the error array and colour the interior of the failing cell
                        CopyAndPasteCount_CO = CopyAndPasteCount_CO + 1
                        CopyAndPasteResultsArray(CopyAndPasteCount_CO, 1) = c.Row - CO_StartRow + 1
                        CopyAndPasteResultsArray(CopyAndPasteCount_CO, 2) = c.Address
                        With c.Interior
                            .ColorIndex = CCellFormatErrorColour
                            .Pattern = xlSolid
                        End With
                    End If
                End If
            End If
        Next
    End If
End If

End Sub

4. As to if you are making a big deal out of nothing, this is linked to answer 1. If you have a limited number of uses, who know how the sheet works and some of its pitfalls, then in-cell data validation may be sufficient for your needs

The solution I now use for data validation is to define a "template" sheet for each sheet I want to validate and within that I define the validation rules for each column. This has the benefits of not being corruptible by a user copying and pasting, and also allows more than 1 validation per column. My code is parameterized, so the same code works across multiple sheets and indeed multiple different workbooks, simply by adhering to the same template structure. This method is also several magnitudes faster than the original code pasted above, so I wont include it here unless you think it is something you would like to consider