输入值后锁定单元格，可以使用正确的密码（VBA）解锁

Question

We have an excel sheet which serves to input data. To protect the data, it must be locked after a value is entered. After mistakes or for corrections later on, it must be possible to change the value after entering a password.

I've been working with a protected sheet, and everytime I try to edit a cell's value, I get a message telling me to unprotect the sheet. As I want the password things to be taken care of in VBA, I wanted an event to be triggered. The problem is, the only event possible is the worksheet_change event. Unfortunately, the event is never triggered as I get the message saying to unprotect the sheet in order to change the value.

I've come up with a temporary solution, but is not 100% user friendly:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Value <> "" Then
    Dim pass As String
        pass = InputBox("Enter Password")
        If pass <> "password" Then
            MsgBox ("Wrong password")
        Else
            Sheets("Blad1").Unprotect password:="password"
            Target.Locked = False
            Target.Value = InputBox("Enter your input")
            Target.Locked = True
            Sheets("Blad1").Protect password:="password"
        End If
    End If
End Sub

I catch the double click event here, which is a before event and is better suited for my needs. This changes the value like it should, but you have to enter the value through an inputbox, which limits to cell linking functionality. It also keeps on generating the message "unprotect the sheet in order to make edits...".

• Is there another approach/solution for my original problem?
• Is there an event better suited for my needs (something like before_change)?
• If above questions cannot be answered, is it possible to get rid of the message to unprotect the sheet?

See answer for detailed solution.

Answer 1

Eventually, I solved it by adding the Worksheet_BeforeDoubleClick event. When they double click on a non empty cell, they are prompted if they want to unlock the sheet. If they click yes, they have to enter the password and then have access to the cells input. To set this up, you must block all cells that may not be changed without password (cells with formula's, headers,...) and leave empty cells unblocked. Afterwards, protect the sheet with the password. Don't forget to put a password on the VBA, or a user who knows how to access it may see the password in the code.

Here's the code I used in my final version:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Value <> "" Then
        changeInput = MsgBox("Do you want to unlock the sheet?", vbYesNo + vbQuestion, "Unlock sheet")
        If changeInput = vbYes Then
            Dim pass As String
            pass = InputBox("Enter Password")
                If pass <> "password" Then
                    MsgBox ("Wrong password")
                Else
                    ActiveSheet.Unprotect Password:="password"
                    Target.Locked = False
                End If
        End If
    End If
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
   Dim cel As Range
    ActiveSheet.Unprotect Password:="password"
    For Each cel In Target
        If cel.Value <> "" Then
            cel.Locked = True
        End If
    Next cel
    ActiveSheet.Protect Password:="password"
End Sub