在Windows命令提示符下，如果没有输入，如何在一定时间内运行一个命令，如果没有输入，又如何运行？

Question

I wasn't sure how to phrase the question, but here's what I want to do.

If a server process closes (determined by " ping 1.1.1.1 -n 1 -w 3000 >nul "), I want to prompt the user to press any key to close the server, but if the user doesn't press a key have the server run again. Here is my current script:

@echo off
:start
echo (%time%) Server started.
"C:\jdk1.7.0_72\bin\java.exe" -server -d64 -Xmx4G -Xms1G -XX:+UseConcMarkSweepGC -XX:-UseAdaptiveSizePolicy -XX:MaxGCPauseMillis=50 -XX:+DisableExplicitGC -XX:+AggressiveOpts -Xmn512M -jar spigot.jar nogui
echo (%time%) WARNING: Server closed or crashed, restarting.
ping 1.1.1.1 -n 1 -w 3000 >nul
timeout 15
goto start

As you see, I have the restart function already, and it works perfectly. So to clarify: if the user presses a key, the server closes and does not restart. If the user does not press a key, after 15 seconds the server starts again.

Answer 1

It is possible to detect if TIMEOUT counted down to 0, or if the user pressed a key. As long as the timeout interval is >= 10, then the last two characters printed will always be " 0" if TIMEOUT finished counting down. So you simply need to capture the output with a FOR /F command and test the last two characters.

The only potential problem is that you will no longer see the countdown on the screen.

@echo off
for /f "delims=" %%A in ('timeout 15') do set "test=%%A"
if "%test:~-2%" equ " 0" (
  echo The user did NOT press a key
) else (
  echo The user pressed a key
)

If the timeout interval is < 10, then you only check the last character to see if it is 0.

@echo off
for /f "delims=" %%A in ('timeout 5') do set "test=%%A"
if "%test:~-1%" equ "0" (
  echo The user did NOT press a key
) else (
  echo The user pressed a key
)

Regarding how to incorporate this into your code - I'm not positive, because I don't fully understand what your code is supposed to do.

Your PING command cannot possibly determine if the server is down, nor can it shut the server down. All it does is introduce a 3 second delay into your script.

If you want to loop back to :start if TIMEOUT completed without the user pressing a key, then all you need is:

for /f "delims=" %%A in ('timeout 15') do set "test=%%A"
if "%test:~-2%" equ " 0" goto start

Answer 2

timeout does not return an errorlevel Request for inclusion in W10 here hence using timeout , the only apparent way would be to save the %time% before and see whether the %time% after is 15 sec later - and that's fraught with problems.

timeout appears to count the period from invocation to the end of that second as the first second the actually terminate the "second" at ~150ms into the next second (may depend on CPU load.)

Consequently, the timining is, to use a tachnical term, "hairy." That first "second" can be anthing from 150mSec or so to 1150mSec, just add 1000mS for each extra second it's given to timeout (15 sec = 14.15Sec..15.15Sec, for instance)

Possibly a better method would be to use choice - reappearing on W7+ AFAIAA. Essentially, that restricts the "interrupting" keyset to alphamerics amd some others - Space for instance isn't available as a "choice" IIRC.