为什么我不能使用（cnt < - hGetContents h）表达式而不是cnt？

Question

I learn Haskell. It works fine:

import System.IO

main = do
  h <- openFile "text.txt" ReadMode
  cnt <- hGetContents h
  mapM_ putStrLn $ lines cnt
  hClose h

But this isn't working:

import System.IO

main = do
  h <- openFile "text.txt" ReadMode  
  mapM_ putStrLn $ lines (cnt <- hGetContents h)
  hClose h

Why my second variant isn't working? I expected both variants are equal, because the (cnt <- hGetContents h) is an expression and returns the value too.

Answer 1

The problem is that cnt <- hGetContents h is not an expression, it's some special syntax sugar inside do notation . This means it is a different way of writing the following normal Haskell code:

hGetContents h >>= \ cnt -> {- rest of do block -}

The part before the {- rest of the do block -} is not a whole expression here, because the rest of the do block is needed to complete the lambda's body.

You could desugar it manually to get something like:

hGetContents h >>= \ cnt -> mapM_ putStrLn (lines cnt)

or the point-free version

hGetContents h >>= mapM_ putStrLn . lines

You can tell that it's a special expression because it introduces a new identifier ( cnt ) that you can use in the rest of your code, outside of the expression itself. This is not something that normal Haskell expressions get to do (at least without compile-time magic).

Answer 2

cnt <- hGetContents h is essentially syntactical sugar for hGetContents h >>= \\cnt -> .

It is not an expression, it is sugar intended for its own line in a do-block.

If you still want to keep it on one line, you can do this, though you will not be able to refer to the file's contents later on:

import System.IO

main = do
  h <- openFile "text.txt" ReadMode  
  hGetContents h >>= mapM_ putStrLn . lines
  hClose h