在Stata中的循环中删除各种字符串变量

Question

I want to a drop a great number of string variables that contain the word "Other" in their observations. As such, I tried the following loop to drop all the variables:

foreach var of varlist v1-v240 { 

drop `var' if  `var'=="Other"

}

What I get in return is the answer "syntax error". I would like to know not only a way to perform the task of dropping all the variables that contain the word "Other", but also why the code that I've entered returns an error.

Answer 1

The short answer on why your syntax is illegal, which @Dimitriy Masterov doesn't quite spell out, is that drop supports just two syntaxes, which can't be mixed, drop ping variables and drop ping observations. This is documented: see eg http://www.stata.com/help.cgi?drop and the corresponding on-line help and manual entry within Stata.

In addition to other solutions, findname from the Stata Journal would allow this solution:

findname, any(@ == "Other") 
drop `r(varlist)' 

Your interpretation of contain is evidently 'is equal to' judging by your use of == as an operator, echoed above. If contain really means 'includes as substring', then you need a syntax such as

any(strpos(@, "Other"))  

or

any(regexm(@, "Other"))  

as @Dimitriy also explains.

Answer 2

If they are actual strings, this should work:

sysuse auto, clear

ds, has(type string) // get a list of string variables

// loop over each string variable, count observations that contain Buick anywhere, and drop the variable if N>0
foreach var of varlist `r(varlist)' {
    count if regexm(`var',"Buick") 
    if r(N)>0 {
        drop `var'
    }
}

If "contains" means only contains, then you need to use "^Buick$" instead or

count if `var'=="Buick"

Beware of leading/trailing spaces.

The if qualifier restricts the scope of a command to those observations for which the value of the expression is true. Your code errors because you are asking Stata to drop a variable (a column) if some observations (rows) satisfy a condition. You could use the if qualifier to drop those observations or you can drop a variable, but not both simultaneously. My code uses the if command (a different beast) to verify the condition, and then drops the variable if that condition is satisfied.

You might be tempted to do something like

if `var'=="Other" {
 drop `var'
}

but that will usually not work as expected (it would drop the variable only if the first observation was "Other").