可以使用IndexOf在Delphi的TStringList中搜索两个或多个备用字符串吗？

Question

I have used IndexOf() in order to extract the index of a TStrinList in Delphi 2005. At the moment it only searches for one string but I would like it to search for alternative strings. For example, to search for 'String A', 'String B' or 'String C' and give me the index of whichever is found first.

Is it possible to do this with IndexOf() or is there another method?

Answer 1

There is no built in functionality that does this.

You can use multiple calls to IndexOf . Then take the smallest index that is not equal to -1 . This is quick and easy to implement but will not have optimal performance.

Another option, if performance is critical, would be to roll your own function to perform the search. Simple enough linear search for unordered lists. A bit more complex if you want to use binary search on an ordered list.

Answer 2

There's no built-in method to do this, and no way to use a single call to IndexOf to achieve it either.

If you need to find the one that occurs first, you'll need to make three separate calls to IndexOf , one for each of the values, and return the one with the lowest index. An easy wrapper to do so would be something like this (along with a console application to test it):

program Project2;

{$APPTYPE CONSOLE}

uses
  System.SysUtils, Classes;


function GetLowestIndexOf(const SL: TStrings; const AValues: array of string): Integer;
var
  Idx, Temp: Integer;
begin
  // Initialize with first test results (which may be -1)
  Result := SL.IndexOf(AValues[0]);
  for Idx := 1 to High(AValues) do
  begin
    Temp := SL.IndexOf(AValues[Idx]);
    if (Temp > -1) and ((Temp < Result) or (Result = -1)) then
      Result := Temp;
  end;
end;

var
  Test: Integer;
  SL: TStringList;

begin
  SL := TStringList.Create;
  SL.Text := 'Some Value'#13'String C'#13'Another Value'#13'Something Else'#13 +
             'String A'#13'Yet Another'#13'String B';
  Test := GetLowestIndexOf(SL, ['String A', 'String B', 'String C']);
  WriteLn(SL[Test]);
  ReadLn;
end.

If your list of items to check for is long, it might be worthwhile to add in an additional test to break out of the loop if you've already found the lowest possible index (between 1 and the length of the shortest value), as there can't be one.