VBA Excel：关闭但不是从Workbook_BeforeClose函数调用宏？

Question

Simply put chaps I want to call a macro just before a workbook closes. You may say why not just put it into the ThisWorkbook section? The reason is that I am uploading a code module via VBA when the book is initially created. So there are basically two solution to this I just cannot figure it out

1. Call a sub based in a standard module before the close of the book
2. Find a way to upload with a VBA procedure a code sub into the ThisWorkbook section when the book is created

Any suggestion?

Answer 1

I agree with Gary that it's probably best to use templates for this, but in any case here is an example of using VBA to add code to an existing VBModule, and to add a new standard module with code.

Obviously, the more complicated are the procedure's you're trying to add, the more difficult it will be to do this by building the strings in the procedure. You can add modules from file (assuming you've exported them -- which you can also do via VBA...) or you can also copy from existing modules in open workbooks, etc. For how to do these things, please refer to the link provided below.

NOTE You will need to enable the application to Trust Access to the VBA Project Object Model (File > Options > Trust Center > Trust Center Settings > Macro Settings > Trust Access to the VBA Project Object Model)

Option Explicit

Sub AddWorkbookWithCode()

Dim wb As Workbook
Set wb = Workbooks.Add

AddVBCodeToWorkbook wb

End Sub
Sub AddVBCodeToWorkbook(wb As Workbook)
Dim procString$

procString = "Sub Workbook_BeforeClose()"
procString = procString & vbCrLf & vbTab & "On Error Resume Next"
procString = procString & vbCrLf & vbTab & "Call SayGoodby"
procString = procString & vbCrLf & "End Sub"

'## Insert some code to ThisWorkbook module:
With wb.VBProject.VBComponents("ThisWorkbook")
    .CodeModule.AddFromString procString
End With

'## Add a new standard module and insert some code there, too:
procString = "Public Sub SayGoodby()"
procString = procString & vbCrLf & vbTab & "MsgBox ""Goodby!"""
procString = procString & vbCrLf & "End Sub"

With wb.VBProject.VBComponents.Add(1)
    .Name = "Module1"
    .CodeModule.AddFromString procString
End With



End Sub

HERE is some good reference material on programming the VBE.

Answer 2

Say at run-time we insert a module and in that module place a Public sub:

Then in the workbook code area:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    On Error Resume Next
    Call SayGoodby
End Sub