Excel自动将单元格范围转换为另一张纸上的图片并自动更新

Question

I want to creat an excel workbook that can convert cell rang on a sheet to picture on another sheet and is capable of authomatically updating the picture should there be any modification on the source sheet. I have no macros background.

Answer 1

Here is an example that you can adapt. We want to capture changes to range C3:F10

These are input changes rather than the result of calculation.

If the cells in this block are changed, the block is copied as Picture and the Picture pasted in Sheet3 near cell C5

Insert the following Event macro in the worksheet code area:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim r1 As Range, r2 As Range, sv As Range
    Dim sh As Worksheet
    Set r1 = Range("C3:F10")
    Set r2 = Sheets("Sheet3").Range("C5")

    If Intersect(Target, r1) Is Nothing Then Exit Sub

    Set sv = Selection
    Set sh = ActiveSheet

    Application.EnableEvents = False
        r1.CopyPicture Appearance:=xlScreen, Format:=xlPicture
        Sheets("Sheet3").Select
        On Error Resume Next
            ActiveSheet.Shapes("Latest Snap").Delete
        On Error GoTo 0
        r2.Select
        ActiveSheet.Paste
        Selection.Name = "Latest Snap"
        sh.Select
        sv.Select
    Application.EnableEvents = True
End Sub

Because it is worksheet code, it is very easy to install and automatic to use:

1. right-click the tab name near the bottom of the Excel window
2. select View Code - this brings up a VBE window
3. paste the stuff in and close the VBE window

If you have any concerns, first try it on a trial worksheet.

If you save the workbook, the macro will be saved with it. If you are using a version of Excel later then 2003, you must save the file as .xlsm rather than .xlsx

To remove the macro:

1. bring up the VBE windows as above
2. clear the code out
3. close the VBE window

To learn more about macros in general, see:

http://www.mvps.org/dmcritchie/excel/getstarted.htm

and

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

To learn more about Event Macros (worksheet code), see:

http://www.mvps.org/dmcritchie/excel/event.htm

Macros must be enabled for this to work!