在Fortran中将DO和IF组合在一起时出错

Question

This is a part of code that I am writing in Visual FORTRAN 6.6A:

  .
  .
  .
   DO 24 I=1,80
24 IF ((NODNUM(1) .EQ. I) .AND. (CAUCHY(3,2) .LT. CTI(I+12))) THEN
      ARRAY(1)=C1*0.99
      END IF
  .
  .
  .

and this error occurs when I compile it:

*--------------------Configuration: ovl30u_moon1 - Win32 Debug--------------------
Compiling Fortran...
C:\\Documents and Settings\\XPMUser\\Desktop\\ovl30u_moon1.f

C:\\Documents and Settings\\XPMUser\\Desktop\\ovl30u_moon1.f(567) : Error: This is not a valid termination statement for a DO construct.

24 IF ((NODNUM(1) .EQ. I) .AND. (CAUCHY(3,2) .LT. CTI(I+12))) THEN
---^

C:\\Documents and Settings\\XPMUser\\Desktop\\ovl30u_moon1.f(569) : Error: An ENDIF occurred without a corresponding IF THEN or ELSE statement.
END IF
-----------^

Error executing df.exe.
ovl30u_moon1.obj - 2 error(s), 0 warning(s)*

I also tried this but error exists yet:

   DO 24 I=1,80
24 IF ((NODNUM(1) .EQ. I) .AND. (CAUCHY(3,2) .LT. CTI(I+12))) THEN
      ARRAY(1)=C1*0.99
      END IF
   END DO

Any advice appreciated.

Answer 1

The termination of a do loop using a label is not valid the way you specify it. For FORTRAN 77 use:

   DO 24 I=1,80
      IF ((NODNUM(1) .EQ. I) .AND. (CAUCHY(3,2) .LT. CTI(I+12))) THEN
          ARRAY(1)=C1*0.99
      END IF
24 CONTINUE

In Fortran 90+ you could simply leave out the label:

   DO I=1,80
      IF ((NODNUM(1) .EQ. I) .AND. (CAUCHY(3,2) .LT. CTI(I+12))) THEN
          ARRAY(1)=C1*0.99
      END IF
   END DO

Or, if you depend on the label, you could use

   label: DO I=1,80
      IF ((NODNUM(1) .EQ. I) .AND. (CAUCHY(3,2) .LT. CTI(I+12))) THEN
          ARRAY(1)=C1*0.99
      END IF
   END DO label

Answer 2

To add to Alexander Vogt's answer there is another way to restate your particular case.

While it is not allowed to use an if construct as the termination of the non-block (labelled) do it is possible to use an if statement:

   DO 24 I=1,80
24 IF ((NODNUM(1) .EQ. I) .AND. (CAUCHY(3,2) .LT. CTI(I+12))) ARRAY(1)=C1*0.99

You can, but you really shouldn't: use the block construct as in the other anwer.

For more detail, see Fortran 2008 8.1.6.3 and R214.