如何以[Int]而不是String的形式读取文件？

Question

I need to read file as bytes, not as chars. But when I do getLine or getContents I get IO String, and need [Int], not String. What should I do?

Answer 1

There is Data.ByteString which has an internal representation of strict Word8 arrays.

You use it pretty much as what you are already used to. Import it qualified, eg

import qualified Data.ByteString as B

and then do stuff like

main = do
  str <- B.getLine
  let bytes = B.unpack str
  print bytes

I am not sure how you got to believe that you need Int. You want a proper byte representation, eg Word8 .

Answer 2

You likely are asking for some form of deserialization, which should be thought of as a separate step. First consider that you're reading in a binary file of some sort (ie it is not text). For this we probably want a bytestring and can do:

import qualified Data.ByteString.Lazy as BL
...
    contents <- BL.readFile someFile

After getting the contents of the file we can convert them from whatever form ( String , Text , ByteString etc). You say you want [Int] but that doesn't tell us what form the data is in - are these 32 bit integers in big endian? 64 bits? How many are there, do you know? Lets assume 32 bit big endian ints... and lets assume the file consists purely of these values:

import qualified Data.ByteString.Lazy as BL
import Data.Binary.Get
import Control.Monad
import Foreign.Storable 
import Data.Word 

readAndDecode :: FilePath -> IO [Int]
readAndDecode someFile =
  do contents <- BL.readFile someFile
     let nrWord32 = fromIntegral (BL.length contents) `div` sizeOf (undefined :: Word32)
     return $ runGet (map fromIntegral `fmap` replicateM nrWord32 getWord32be) contents

That is, we read the file, compute the number of 32 bit words in the file, decode, and convert each Word32 into an Int