是否可以使用XSLT 2.0将简约的XML转换为完整的HTML表？

Question

VERY IMPORTANT NOTE: I am using QtXmlPattern (a not fully implemented XSLT 2.0 processor with a few bugs in what's implemented...)

I have a well formed XML file with data defined in a four level array as in:

<a>
  <b>
    <c day="20150221">
      <d>...</d>
      <e>...</e>
    </c>
    <c day="20150222">
      <d>...</d>
      <e>...</e>
    </c>
    <c day="20150223">
      <d>...</d>
      <e>...</e>
    </c>
  </b>
  <b>
    <c day="20150219">
      <d>...</d>
      <e>...</e>
    </c>
    <c day="20150221">
      <d>...</d>
      <e>...</e>
    </c>
    <c day="20150223">
      <d>...</d>
      <e>...</e>
    </c>
  </b>
  ...
</a>

The result should include all the days, but as we can see each <b> list may have a different set of days. Yet the result needs to have all the days for all the <b> tags. If data is not available, the result remains empty or zero as might be.

I found a way to gather all the days in a variable:

<xsl:variable name="days" select="distinct-values(/a/b/c/@day)"/>

But I don't see how to generate the final results which would look something like this:

<table>
  <th>
    <td>20150219</td>
    <td>20150221</td>
    <td>20150222</td>
    <td>20150223</td>
  </th>
  <tr>
    <td>data from <d> tag on 20150219</td>
    <td>data from <d> tag on 20150221</td>
    <td>data from <d> tag on 20150222</td>
    <td>data from <d> tag on 20150223</td>
  </tr>
  ...[repeat for various data and calculation on the data]...
</table>

My problem is that the variable is not a list of nodes, just a list of strings and I'm not too sure how I can loop through a list of string.

Just in case, for those who do not know about the QXmlQuery parser, the xsl:for-each-group command does not exist.

Answer 1

You can (with XSLT 2.0, not sure whether your chosen processor supports that then) simply do

<xsl:variable name="main-doc" select="/">

to store the main document node in a variable you will later on, then define a key

<xsl:key name="by-date" match="a/b/c/d" use="../@day"/>

and then references d items on a day with

<xsl:for-each select="$days">
  <xsl:variable name="d-on-day" select="key('by-date', ., $main-doc)"/>

That key() call with three argument is new in XSLT 2.0, if not supported then try

<xsl:for-each select="$days">
  <xsl:variable name="day" select="."/>
  <xsl:for-each select="$main-doc">
    <xsl:variable name="d-on-day" select="key('by-date', $day)"/>
    ...
  </xsl:for-each>
  ...
</xsl:for-each>

If the key function is not available then you need to write the references as eg

<xsl:variable name="d-elements" select="/a/b/c/d"/>

<xsl:for-each select="$days">
  <xsl:variable name="day" select="."/>
  <xsl:for-each select="$d-elements[../@day = $day]">...</xsl:for-each>
</xsl:for-each>

Answer 2

I am not exactly sure what you need, but sometimes it is easier to comment on an attempted solution than trying to explain. You definitely have to use a key to find distinct attribute values.

Do not loop through a list of strings, but through a sequence of c elements that are unique with respect to the value of their day attribute (which, in the end, is the same). The technique I use below is described by Jeni Tennison here because it is commonly used for grouping problems.

XML Input

In my opinion, a sensible input includes actual values for d elements:

<?xml version="1.0" encoding="UTF-8"?>
<a>
  <b>
    <c day="20150221">
      <d>data from day 20150221</d>
      <e>...</e>
    </c>
    <c day="20150222">
      <d>data from day 20150222</d>
      <e>...</e>
    </c>
    <c day="20150223">
      <d>data from day 20150223</d>
      <e>...</e>
    </c>
  </b>
  <b>
    <c day="20150219">
      <d>data from day 20150219</d>
      <e>...</e>
    </c>
    <c day="20150221">
      <d>data from day 20150221</d>
      <e>...</e>
    </c>
    <c day="20150223">
      <d>data from day 20150223</d>
      <e>...</e>
    </c>
  </b>
  <!--...-->
</a>

Stylesheet

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="html" doctype-public="XSLT-compat" omit-xml-declaration="yes" encoding="UTF-8" indent="yes" />

    <xsl:key name="day-from-c" match="c" use="@day" />

    <xsl:template match="/">
      <hmtl>
        <xsl:apply-templates/>
      </hmtl>
    </xsl:template>

    <xsl:template match="a">
        <table>

            <xsl:variable name="days" select="b/c[generate-id() =
        generate-id(key('day-from-c', @day)[1])]"/>

            <xsl:for-each select="$days">
                <xsl:sort select="@day"/>
                <th>
                    <xsl:value-of select="@day"/>
                </th>
            </xsl:for-each>
            <tr>
                <xsl:for-each select="$days">
                    <xsl:sort select="@day"/>
                    <td>
                        <xsl:value-of select="/a/b/c[@day = current()/@day]/d"/>
                    </td>
                </xsl:for-each>
            </tr>
        </table>
    </xsl:template>

</xsl:transform>

HTML Output

It is still not clear to me what should happen if there are multiple d elements on the same day.

<!DOCTYPE html
  PUBLIC "XSLT-compat">
<hmtl>
   <table>
      <th>20150219</th>
      <th>20150221</th>
      <th>20150222</th>
      <th>20150223</th>
      <tr>
         <td>data from day 20150219</td>
         <td>data from day 20150221 data from day 20150221</td>
         <td>data from day 20150222</td>
         <td>data from day 20150223 data from day 20150223</td>
      </tr>
   </table>
</hmtl>

Try this solution online on xsltransform .