交易不提交

Question

In my SSMS I have checked the "SET IMPLICIT_TRANSACTIONS" because I do not want to do any commits automatically. When I run the below code, the transaction still does not get committed. Am I missing something else?

BEGIN TRANSACTION
  BEGIN TRY
    EXECUTE prModifyOrAdd '73891821'
    COMMIT TRANSACTION
  END TRY
  BEGIN CATCH
    PRINT 'ERROR'
  END CATCH

Here is the design of the procedure:

 CREATE PROCEDURE [dbo].[prModifyOrAdd] @id varchar(50) 
 as
 DECLARE @outMessage varchar(25)
 update INDV834
 set FILENAME= @id+'.txt'
 where SUBSCRIBER_ID=@id

 if (select distinct filename from INDV834 where SUBSCRIBER_ID=@id)=      (@id+'.txt')
   BEGIN
    SET @outMessage = 'Completed: ' + (@id+'.txt')
    select @outMessage
   END
 else
   BEGIN
    SET @outMessage = 'Errored'
    select @outMessage
   END

Answer 1

If you start a transaction explicitly, as you did, the set implict is ignored. What is happening in the stored procedure? Does it have its own error handling and is it handling the error before you see it?

Many users wrap their rollback with a @@trancount as so:

begin catch

if @@trancount>0

begin

rollback

end

end

Answer 2

There are few reasons why you don't see the "data committed":

0) If you have checked IMPLICT_TRANSACTION option in SSMS then after BEGIN TRANSACTION will be two active transactions. This means that you need to COMMIT statements.

See also Nesting transactions

Note: At this point ( IMPLICT_TRANSACTION ON + BEGIN TRANSACTION + just one COMMIT ), concurrent connections will be blocked because a transaction will be active ( SELECT @@TRANCOUNT ). And, if you close SSMS window, current [implicit] transaction will be automatically cancelled (ROLLBACK) => you will loose any modifications made by stored procedure.

My recommendation is to avoid IMPLICT_TRANSACTION . So, please uncheck this option.

1) INSERT / UPDATE / DELETE / MERGE statements from dbo.prModifyOrAdd could afftect 0 rows. For example, an UPDATE statement may have WHERE clause but conditions from WHERE are false , so 0 rows are updated.

2) Target tables have INSTEAD OF triggers that do nothing or have some bugs .

Example:

CREATE TABLE dbo.MyTable (ID INT IDENTITY(1,1) PRIMARY KEY, Col1 INT)
GO
INSERT dbo.MyTable VALUES (11)
INSERT dbo.MyTable VALUES (22)
GO

CREATE TRIGGER trgTrivialInsteadOfTrigger 
ON dbo.MyTable
INSTEAD OF UPDATE
AS
BEGIN
    PRINT 'trgTrivialInsteadOfTrigger activated'
END;
GO

UPDATE   dbo.MyTable
SET     Col1 = Col1 * 10;
SELECT * FROM dbo.MyTable;
GO
/*
-- Col1 isn't updated 11 -> 110 ...
ID          Col1
----------- -----------
1           11
2           22

(2 row(s) affected)
*/

3) You source code is executed in the context of another transaction that execute at the end ROLLBACK (see nesting transactions):

BEGIN TRANSACTION

... your source code ...

ROLLBACK <-- this statement will cancel all modifications 

Example:

DROP TRIGGER dbo.trgTrivialInsteadOfTrigger -- <-- see 2)
GO

BEGIN TRANSACTION
    BEGIN TRANSACTION 
        UPDATE   dbo.MyTable
        SET     Col1 = Col1 * 10;
    COMMIT
ROLLBACK
SELECT * FROM dbo.MyTable;
/*
ID          Col1
----------- -----------
1           11
2           22

(2 row(s) affected)
*/