Excel 2007 VBA - 使用VLOOKUP在不同工作表中查找值并将结果存储在活动工作表中

Question

I am new to this group and VBA.

I have a worksheet 'T2', with a variable number of rows. Starting with row 3, I want to look up the item number found in column 'E' and search worksheet 'Support'. The item number can be found somewhere in column 'A' in 'Support'. I need to bring the value in column 'B' in Support (that relates to that item number) and store it in column 'A' in worksheet 'T2'. I then want to repeat this process for every row in 'T2' up to and including the last row.

Can anyone help please as I just can't get this to work at all.

Thanks

Answer 1

For the Vlookup part, this should be what you need.

Sub with_some_name

Dim result As String

With Worksheets("T2")
result = Application.WorksheetFunction.VLookup(.Range("e3"), Worksheets("support").Range("A:B"), 2, False)
Range("A3").Value = result
End With

end sub

Answer 2

variant using Dictionary:

Sub Test1()
    Dim Dic As Object, key As Variant, oCell As Range, i&
    Dim w1 As Worksheet, w2 As Worksheet

    Set Dic = CreateObject("Scripting.Dictionary")
    Set w1 = Sheets("Support")
    Set w2 = Sheets("T2")

    i = w1.Cells(Rows.Count, "A").End(xlUp).Row

    For Each oCell In w1.Range("A1:A" & i)
        If Not Dic.exists(oCell.Value) Then
            Dic.Add oCell.Value, oCell.Offset(, 1).Value
        End If
    Next

    i = w2.Cells(Rows.Count, "E").End(xlUp).Row

    For Each oCell In w2.Range("E3:E" & i)
        For Each key In Dic
            If oCell.Value = key Then
                oCell.Offset(, -4).Value = Dic(key)
            End If
        Next
    Next
End Sub

variant using vlookup:

Sub Test2()
    Dim oCell As Range
    Dim w1 As Worksheet, w2 As Worksheet

    Set w1 = Sheets("Support")
    Set w2 = Sheets("T2")

    i = w2.Cells(Rows.Count, "E").End(xlUp).Row
On Error Resume Next
    For Each oCell In w2.Range("E3:E" & i)
        oCell.Offset(, -4).Value = WorksheetFunction.VLookup(oCell.Value, w1.[A:B], 2, 0)
    Next
End Sub

variant using find method:

Sub Test3()
    Dim oCell As Range
    Dim w1 As Worksheet, w2 As Worksheet

    Set w1 = Sheets("Support")
    Set w2 = Sheets("T2")

    i = w2.Cells(Rows.Count, "E").End(xlUp).Row
On Error Resume Next
    For Each oCell In w2.Range("E3:E" & i)
        oCell.Offset(, -4).Value = w1.Cells(w1.Columns(1).Find(oCell.Value).Row, 2).Value
    Next
End Sub

output result