在VB.NET中使用带有数组的CSV .txt文件来编辑数据？

Question

I'm a beginner trying to learn VB.NET and I'm not quite sure how I'll explain this, but I'll give it a shot. Basically, I've written a txt file with about 10 lines of data in CSV form.

For example:

John, 10, 14
Michael, 14, 27
Billy, 13, 45 
etc, etc....

I just want to be able to read and edit particular lines - not necessarily add new lines.

Just wondering if someone could just outline how I'd go about this - not asking anyone to write the program for me. I just don't know what to do and I couldn't understand other answers I've found on SO that attempted to solve the same problem. I don't know if I'm just a bit dense or something so it'd be great if someone could perhaps give a simple, 'dumbed-down' outline of what I need to do.

Thank you.

Answer 1

as stated in the comments you usually read all the file into memory, manipulate it and write it all back.

dotnet has a method that puts a file content in an array (line by line)

if you need to access individual cells in the CSV you probably want to run the split method on each line and join to merge them back together.

the split/join methods are either an method of the string/array object or its in the Strings namespace

a method for writing the file back is also in the System.IO Namespace

Answer 2

You don't asking to write the code for you, I can understand you but I think there is no way to show how can you do that. I used split/join methods as @weberik mentioned. It is a simple console application:

Public Class Sample

    Public Shared Sub Main()
        CreateExampleFileIfNotExists()
        'lines variable is an "Array"
        Dim lines() As String = IO.File.ReadAllLines("Example.txt")
        'write items to the console
        ShowItems(lines, "Values before edit:")
        'edit the items
        EditItems(lines)
        'write edited items to the console
        ShowItems(lines, "Values after edit:")
        'save changes?
        Save(lines)
        'finish
        Console.WriteLine("Press any key to exit.")
        Console.ReadKey()
    End Sub

    Public Shared Sub ShowItems(lines() As String, header As String)
        Console.WriteLine(header)
        Dim headers() As String = {"Name:", "Value1:", "Value2:"}
        WriteItems(headers)
        For Each line In lines
            WriteItems(line.Split(","))
        Next
    End Sub

    Public Shared Sub EditItems(lines() As String)
        For i As Integer = 0 To lines.Length - 1
            Dim line As String = lines(i)
            Dim values() As String = line.Split(",")
            'edit the item
            values(0) = "Edited " & values(0)
            values(1) += i
            values(2) *= i
            lines(i) = String.Join(",", values)
        Next
        Console.WriteLine() 'empty line
    End Sub

    Public Shared Sub WriteItems(itemValues() As String)
        Dim line As String = ""
        For Each item In itemValues
            line &= item & vbTab & vbTab
        Next
        Console.WriteLine(line)
    End Sub

    Public Shared Sub CreateExampleFileIfNotExists()
        If Not IO.File.Exists("Example.txt") Then
            IO.File.WriteAllLines("Example.txt", {"John,10,14", "Michael,14,27", "Billy,13,45"})
        End If
    End Sub

    Public Shared Sub Save(lines() As String)
        Console.WriteLine(vbCrLf & "Do you want to save the changes? Y/N")
        Dim result = Console.ReadKey()
        Console.WriteLine()
        Select Case result.Key
            Case ConsoleKey.Y
                IO.File.WriteAllLines("Example.txt", lines)
                Console.WriteLine("The changes has been saved.")
        End Select
    End Sub

End Class