使用VBA在Access上创建登录表单

Question

I am trying to create a login for my Access db, but I can't get it to work. Here is my code (keep in mind "Preparer" is the name of the table holding username and password info:

Private Sub Command1_Click()

    If IsNull(Me.txtLogin) Then

        MsgBox "Please Enter Login", vbInformation, "Need ID"
        Me.txtLogin.SetFocus

    ElseIf IsNull(Me.txtPassword) Then

        MsgBox "Please Enter Password",vbInformation, "Need Password"    
        Me.txtPassword.SetFocus

    Else

        If ((IsNull(DLookup("Login","Preparer","Login='& Me.txtLogin.Value &'"))) or _
        (IsNull(DLookup("Password","Preparer","Password='& Me.txtPassword.Value &'")))) Then

            MsgBox "Incorrect Login or Password"

        Else

            DoCmd.Close    
            MsgBox "Success"

            DoCmd.OpenForm "Master"

        End If

    End If

End Sub

The first two parts work so if login or password is blank it gives the correct error message, but whenever I put a login and password, even if they are correct (ie they exist in the preparer table) it gives me the "Incorrect Login or Password"

I'm assuming the problem is in the code here:

If ((IsNull(DLookup("Login","Preparer","Login='& Me.txtLogin.Value &'"))) or _
    (IsNull(DLookup("Password","Preparer","Password='& Me.txtPassword.Value &'")))) Then

    MsgBox "Incorrect Login or Password"

Anyone understand why I can't get to the bottom else statement?

Answer 1

You are not comparing the right information. You should be checking if the Password entered for that Username exists in the table. So your code should be changed to just one single DLookup, as.

Private Sub Command1_Click()
    If IsNull(Me.txtLogin) Then
        MsgBox "Please Enter Login", vbInformation, "Need ID"
        Me.txtLogin.SetFocus
    ElseIf IsNull(Me.txtPassword) Then
        MsgBox "Please Enter Password",vbInformation, "Need Password"    
        Me.txtPassword.SetFocus
    Else
        If Nz(DLookup("Password", "Preparer", "Login = '" & Me.txtLogin.Value & "'")), "GarbageEntry") = Me.txtPassword Then
            DoCmd.Close    
            MsgBox "Success"
            DoCmd.OpenForm "Master"
        Else
            MsgBox "Incorrect Login or Password"
        End If
    End If
End Sub

In the above code, you first use the DLookup to retrieve the Password for the username. IF the username matches, a Password will be returned, ELSE a default value of " GarbageEntry " is returned. So the Right password (or) GarbageEntry is compared with the actual password entered. If they are the same then you give them access. Else a message.

Hope this helps !