SQL中的复杂更新/联接

Question

I have some complex join statement and want to make it easier.(or stay it but make working right :))

CREATE TABLE #Temp1
(
    ID      INT IDENTITY,
    Name1   VARCHAR(100),
    Value1  INT
)


CREATE TABLE #Temp2
(
    ID      INT IDENTITY,
    Name2   VARCHAR(100),
    Value2  INT,
    Value1  INT
)


INSERT INTO #Temp1
SELECT 'Nm_1', 111 UNION ALL
SELECT 'Nm_2', 222 


INSERT INTO #Temp2(Name2, Value2)
SELECT 'Nm_3', 333 UNION ALL
SELECT 'Nm_4', 444 UNION ALL 
SELECT 'Nm_5', 555 UNION ALL
SELECT 'Nm_6', 666 UNION ALL
SELECT 'Nm_7', 777 UNION ALL
SELECT 'Nm_8', 888 UNION ALL
SELECT 'Nm_9', 999 UNION ALL
SELECT 'Nm_4', 444 UNION ALL 
SELECT 'Nm_5', 555 UNION ALL
SELECT 'Nm_6', 666 UNION ALL
SELECT 'Nm_7', 777 UNION ALL
SELECT 'Nm_8', 888 UNION ALL
SELECT 'Nm_9', 999 UNION ALL
SELECT 'Nm_10',100 UNION ALL
SELECT 'Nm_11',110

Here is two tables. First table in ordinary which can have any number of rows. Second depends on first one.I explain how. First row in #Temp2 table is static, rows from 2 to 7 repeated as much as count from #Temp1 is and last 3 rows are also static.

In my examle I have two row in #Temp1, so

SELECT 'Nm_4', 444 UNION ALL 
SELECT 'Nm_5', 555 UNION ALL
SELECT 'Nm_6', 666 UNION ALL
SELECT 'Nm_7', 777 UNION ALL
SELECT 'Nm_8', 888 UNION ALL
SELECT 'Nm_9', 999 UNION ALL

are twice, if i have 3 there will be 6 * 3 row.

Now I want to make update Value1 column in #Temp2 table in such way.

select Value1 from #Temp1 where ID =1

this value would be written in #Temp2 table where ID>=2 and ID<=7

select Value1 from #Temp1 where ID =2

should be in #Temp2 table where ID>=8 and ID<=13.

I try to write join like this

UPDATE #Temp2
SET Value1 = a.Value1
FROM #Temp1 AS a
INNER JOIN #Temp2 AS b
    ON 2*a.ID - b.ID IN (-(2*a.ID-1)-(a.ID-2),
                         -(2*a.ID-1)-(a.ID-1),
                         -(2*a.ID-1)-(a.ID-0),
                         -(2*a.ID-1)-(a.ID+1),
                         -(2*a.ID-1)-(a.ID+2),
                         -(2*a.ID-1)-(a.ID+3))

But it's wrong, if you run this script you can see. Can anybody help?

Join should be obviously made with ID column

Answer 1

This simple join work:

UPDATE #Temp2
SET Value1 = a.Value1
FROM #Temp1 AS a
INNER JOIN #Temp2 AS b
ON b.ID BETWEEN (a.ID*6-4) AND (a.ID*6+1)

Answer 2

You can use a SubQuery with CASE WHEN . And you can use the BETWEEN tag to handle your IDs.

UPDATE #Temp2
SET #Temp2.Value1 = (CASE WHEN ID BETWEEN 2 AND 7 THEN (SELECT a.Value1 FROM #Temp1 a WHERE a.ID = 1)
                          WHEN ID BETWEEN 8 AND 13 THEN (SELECT a.Value1 FROM #Temp1 a WHERE a.ID = 2)
                     END)
WHERE #Temp2.ID BETWEEN 2 AND 13

Answer 3

You could try this which should solve your problem:

DECLARE @Counter int = 0,
        @Rows int

Set @Rows = (Select count(*) from #Temp1)

While (@Counter < @Rows)
Begin

    Update #Temp2
    Set Value1 = (Select Value1 from #Temp1 where ID = @Counter + 1)
    Where ID between 2 + (@Counter * 6) and 7 + (@Counter * 6)
    Set @Counter = @Counter + 1

End