如何在Linux中对大于值的行进行计数并将计数写入文本文件

Question

I have a file with sample data shown below:

%_above_10 %_above_20 %_above_30 %_above_50
88.6    88.1    87.8    87.2
89.1    78.5    72.3    59.4
100.0   100.0   100.0   100.0
100.0   100.0   100.0   100.0
100.0   100.0   70.0   80.0
100.0   100.0   100.0   80.0
100.0    31.9    26.8    17.4
00.0   96.0    77.3    43.3
68.8    65.9    63.6    57.1

I need to count the rows in each column which have value 100 and write it to a text file. The output could look like:

Totalrows %_above_10 %_above_20 %_above_30 %_above_50
   9        5            4          3         2

I am able to count one column at a time using the basic awk command:

awk -F "\t" '{if($1 == 100)print;}

Could anyone suggest a way to count the columns in the above specified way and write to a file using linux commands or script (awk). Thanks

Answer 1

A way with awk and column.

awk 'NR==1{print "TotalRows "$0;next}
     {for(i=1;i<=NF;i++)a[i]+=$i==100}
     END{print NR-1,a[1],a[2],a[3],a[4]}' file | column -t

More general

 awk 'NR==1{print "TotalRows "$0;next} 
      {a[0]++;for(i=1;i<=NF;i++)a[i]+=$i==100}
      END{for(i=0;i<=NF;i++)printf "%s ",a[i];print t}' test | column -t

---

Output

TotalRows  %_above_10  %_above_20  %_above_30  %_above_50
9          5           4           3           2

Answer 2

Awk solution:

$ cat chas.awk
NR == 1 { hdr = $0; next }    
{
    a[1] += ($1 == 100) ? 1 : 0;
    a[2] += ($2 == 100) ? 1 : 0;
    a[3] += ($3 == 100) ? 1 : 0;
    a[4] += ($4 == 100) ? 1 : 0;
}
END { print "Totalrows", hdr; print (NR-1),a[1],a[2],a[3],a[4] }

$ awk -f chas.awk chas.txt
Totalrows %_above_10 %_above_20 %_above_30 %_above_50
9 5 4 3 2

Or a more general solution with respect to the number of columns:

NR == 1 { hdr = $0; cols = NF; next }

{
    for (i=1; i<=NF; ++i) {
      a[i] += ($i == 100) ? 1 : 0;
    }
}

END {
    print "Totalrows", hdr
    printf (NR-1)
    for (i=1; i<=cols; ++i) {
      printf " " a[i]
    }
    print "" # add final newline
}

Answer 3

Perl solution:

perl -lane '$F[$_] == 100 and $c[$_]++ for 0 .. $#F }{ print $.-1, " @c"' < input

• -l adds a newline to print
• -a splits the input to the @F array
• for each line, the script goes over the records and adds 1 to the particular counter if it sees 100
• once the file ends, the counter is printed, preceded by the number of files read minus one (you don't count the header)