将Excel数据导出到Word模板

Question

ID          Employee    Date       
1234        me          11/03/2015
9999        U           11/03/2015
1111        Us          11/03/2015 

Hi,

I have the above table in excel that is populated when a user completes a userform and clicks a 'Save' Button. Once they have saved an 'Export' button is enabled and the user can export the last record (row) submitted by the user form to a word template in the relevant locations on the template. I have created bookmarks in the attached word template for ID,Employee and Date and would like the data to be exported to these locations.

I've written the following code on the 'Export' button but I can't seem to get the export to work. the code runs up until the template is opened but the posting of the data to the bookmarks causes an error.

Sub PDFExportRow()
    Dim WRD As Object, DOC As Object, ac As Long
    On Error Resume Next
    Set WRD = CreateObject("Word.Application")
    If Err.Number <> 0 Then
  Set WRD = CreateObject("Word.Application")
  End If
  On Error GoTo 0

  Set DOC = WRD.Documents.Open("C:\RC_QA_TEST\Template\QA_REPORT.dotm")


WRD.Visible = True
ac = ActiveCell.Row

With DOC
.FormFields("ID").Result = Cells(ac, "A")
.FormFields("Employee").Result = Cells(ac, "B")
.FormFields("Date").Result = Cells(ac, "C")

End With

'set active printer to one you use here
WRD.ActivePrinter = "CutePDF Writer"
'print document
DOC.PrintOut
'close document without saving
DOC.Close False
'close application
WRD.Quit
Set WRD = Nothing
Set DOC = Nothing


End Sub

Any help on this is greatly appreciated.

Answer 1

If the code is having errors starting with the DOC.FormFields part, then I think the problem is that you haven't actually used Form Fields, you have used bookmarks, so you need to use the appropriate methods.

Try this:

With DOC
.Bookmarks("ID").Range.Text = Cells(ac, "A")
.Bookmarks("Employee").Range.Text = Cells(ac, "B")
.Bookmarks("Date").Range.Text = Cells(ac, "C")

End With

Note that once you update the text in a bookmark, the bookmark is removed from the document. Since you are closing the document without saving it, when you reopen, the bookmark will be there again, but you would need to reset the bookmark if you were to save the word doc, or keep it open and try to replace the text again.