在每个数据库的动态SQL中创建用户

Question

I want to be able to create a user for a login and assign some permission, and I want to do this for databases whose name is > 4 Here's what I have

 EXEC sp_MSForEachDB 'Declare @name varchar(100), @UserToAdd VARCHAR(100) = ''HQ\\tname'' select @name = ''?'' PRINT @name IF db_id(@name) > 4 BEGIN USE ? EXEC (''CREATE USER ['' + @UserToAdd + ''] FOR LOGIN ['' + @UserToAdd + ''];'') EXEC (''EXEC sp_addrolemember N''db_datareader'', N'''' + @UserToAdd + '''';'') END' 

I'm having some trouble with the syntax using multiple quotes, If I just run this for an individual database I know it works using the following code

 DECLARE @UserToAdd VARCHAR(100) = 'HQ\\tname' BEGIN USE [dbnamehere] EXEC ('CREATE USER [' + @UserToAdd + '] FOR LOGIN [' + @UserToAdd + '];') EXEC ('EXEC sp_addrolemember N''db_datareader'', N''' + @UserToAdd + ''';') END 

Could anyone help out with the syntax?

Answer 1

One way to do this is with a cursor:

declare 
    @sql nvarchar(max),
    @db sysname,
    @UserToAdd sysname = 'HQ\tname';

declare db_cursor cursor local fast_forward for
select
    name
from
    sys.databases
where
    database_id > 4;

open db_cursor;

fetch next from db_cursor into @db;

while @@fetch_status = 0
begin
    set @sql = 'use ' + quotename(@db) + ';
    create user ' + quotename(@UserToAdd) + ' for login ' + quotename(@UserToAdd) + ';
    exec sp_addrolemember ''db_datareader'', ' + quotename(@UserToAdd, '''') + ';';
    exec sp_executesql @sql;
    fetch next from db_cursor into @db;        
end;

close db_cursor;
deallocate db_cursor;