使用XSLT1.0将两个节点转换为一个

Question

Input:

<cp>
...
<conEmail>eeee</conEmail>
<conPhone>1800<conPhone>
...
</cp>

Output:

<cp>
...
<con>
 <email>eeee</email>
 <phone>1800</phone>
</con>
...
</cp>

Xsl-t

<xsl:template match="*[starts-with(name(), 'con')]">
<xsl:element name="con">
<xsl:element name="email">
    <xsl:value-of select="." />
</xsl:element>
<xsl:element name="phone">
    <xsl:value-of select="following-sibling::*[1]"></xsl:value-of>
</xsl:element>
</xsl:element>
</xsl:template>

I tried to match with *[starts-with(name(), 'con')] but then its matching the nodes twice... Any help?

Answer 1

It is difficult to answer a question that contains only snippets, because the overall context is important.

The following stylesheet:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/cp">
    <xsl:copy>
        <!-- other things? -->
        <con>
            <xsl:apply-templates select="*[starts-with(name(), 'con')]"/>   
        </con>
        <!-- more of other things? -->
    </xsl:copy>
</xsl:template>

<xsl:template match="*[starts-with(name(), 'con')]">
    <xsl:element name="{substring-after(local-name(),'con')}">
        <xsl:value-of select="." />
    </xsl:element>
</xsl:template>

</xsl:stylesheet>

when applied to your input (after correcting the unclosed conPhone tag!), will return:

<?xml version="1.0" encoding="utf-8"?>
<cp>
   <con>
      <Email>eeee</Email>
      <Phone>1800</Phone>
   </con>
</cp>

If you know in advance the names of the "con*" elements, it would be better to handle them explicitly, for example:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/cp">
    <xsl:copy>
        <!-- other things? -->
        <con>
            <xsl:apply-templates select="conEmail | conPhone"/> 
        </con>
        <!-- more of other things? -->
    </xsl:copy>
</xsl:template>

<xsl:template match="conEmail">
    <email>
        <xsl:value-of select="." />
    </email>
</xsl:template>

<xsl:template match="conPhone">
    <phone>
        <xsl:value-of select="." />
    </phone>
</xsl:template>

</xsl:stylesheet>

to return:

<?xml version="1.0" encoding="utf-8"?>
<cp>
   <con>
      <email>eeee</email>
      <phone>1800</phone>
   </con>
</cp>