如何将文本框数组插入数据库？

Question

I have a visual basic TextBox1 with String[] Array lines (output from powershell script)like this sample

3.50
12.59
21.34
31.20
3.80
12.72
21.60
33.43
3.21
12.08
21.30
33.02

I need split these values each 4 line and insert into database like

ResultA    ResultB ResultC ResultD
Test1   3.50    12.59   21.34   31.20


Test2   3.80    12.72   21.60   33.43

Test3   3.21    12.08   21.30   33.02

also if I have more lines on textbox 16,20 or more split to 4 lines and help me to insert into database table. thanks

Answer 1

I'm not familiar with vb but in C# you can do this:

var yourArray = new string[40];
string resA = null, resB = null, resC = null, resD = null;

for(var i = 0; i<yourArray.Length; i+=4)
{
    resA = yourArray[i];
    if(i+1 < yourArray.Length)
        resB = yourArray[i+1];
    if(i+2 < yourArray.Length)
        resC = yourArray[i+2];
    if(i+3 < yourArray.Length)
        resD = yourArray[i+3];

    /// insert these values to db
}

Answer 2

It's not clear whether you don't know how to insert something into your database or you don't know how to split the text with VB.NET. I presume the latter, otherwise the question is too broad and doesn't contain enough informations.

However, i would first implement a custom class to hold all your informations:

Public Class NumberResults
    Public Sub New(number As Int32, description As String, resA As Decimal, resB As Decimal, resC As Decimal, resD As Decimal)
        Me.Number = number
        Me.Description = description
        Me.ResultA = resA
        Me.ResultB = resB
        Me.ResultC = resC
        Me.ResultD = resD
    End Sub

    Public Property Number As Int32
    Public Property Description As String
    Public Property ResultA As Decimal
    Public Property ResultB As Decimal
    Public Property ResultC As Decimal
    Public Property ResultD As Decimal

    Public Overrides Function ToString() As String
        Return String.Format("{0} {1} {2} {3} {4}", Description, ResultA, ResultB, ResultC, ResultD)
    End Function
End Class

Then you can use LINQ to select every group of four lines parsed to decimal. If you use a TryParse method in a LINQ query you should use a helper method that returns a Nullable(Of T) which is better than using a local variable:

You could these:

Module StringExtensions
    <Extension()>
    Public Function TryGetInt32(Str As String) As Nullable(Of Int32)
        If Str Is Nothing Then Return Nothing
        Dim num As Int32
        If Int32.TryParse(Str, num) Then Return num
        Return Nothing
    End Function

    <Extension()>
    Public Function TryGetIntDecimal(Str As String, Optional provider As IFormatProvider = Nothing) As Nullable(Of Decimal)
        If Str Is Nothing Then Return Nothing
        Dim num As Decimal
        If provider Is Nothing Then provider = Globalization.NumberFormatInfo.CurrentInfo
        If Decimal.TryParse(Str, Globalization.NumberStyles.Any, provider, num) Then Return num
        Return Nothing
    End Function
End Module

Now you get all lines from the textbox that can be parsed to Decimal in this way:

Dim numberLines = From line In TextBox1.Lines
                  Let numOrNull = line.TryGetIntDecimal(CultureInfo.InvariantCulture)
                  Where numOrNull.HasValue
                  Select numOrNull.Value

This LINQ query is deferred executed which means that currently it is a no-op. You could have a look at the values in the debugger, it contains all 12 lines as decimals. Now i use it in this query which does the grouping by using the \\= integer division operator :

Dim results = numberLines.
    Select(Function(num, index) New With {.num = num, .index = index}).
    GroupBy(Function(x) x.index \ 4).
    Select(Function(grp, ix) New NumberResults(
               ix + 1, String.Format("Test{0}", ix + 1),
               grp.Select(Function(x) x.num).First(),
               grp.Select(Function(x) x.num).ElementAtOrDefault(1),
               grp.Select(Function(x) x.num).ElementAtOrDefault(2),
               grp.Select(Function(x) x.num).ElementAtOrDefault(3)))

The queries are still not executed, therefore you could for example use a For Each to insert them into database:

For Each res In results
    Console.WriteLine(res.ToString())
Next

which outputs (i use comma as decimal separator):

Test1 3,50 12,59 21,34 31,20
Test2 3,80 12,72 21,60 33,43
Test3 3,21 12,08 21,30 33,02