VBA Excel宏多次复制第一行，而不是转到第二行

Question

I need your input.

On Sheet 1 "In Stock", I have 13 columns of data with about 300 rows. I need to copy this data into sheet 2 "Low" based on the value of column 11.

If column 11 is less than 98%, I need to copy the data.

Here is my macro:

Dim z As Integer

z = 3

For i = 20 To Worksheets("In Stock").TextBox1.Value
If Worksheets("In Stock").Cells(i, 11) < "98" Then GoTo JMP1
GoTo JMP2

JMP1:
Worksheets("Low").Cells(z, 1).Value = Worksheets("In Stock").Cells(20,   1).Value
Worksheets("Low").Cells(z, 2).Value = Worksheets("In Stock").Cells(20, 2).Value
Worksheets("Low").Cells(z, 3).Value = Worksheets("In Stock").Cells(20, 3).Value
Worksheets("Low").Cells(z, 4).Value = Worksheets("In Stock").Cells(20, 4).Value
Worksheets("Low").Cells(z, 5).Value = Worksheets("In Stock").Cells(20, 5).Value
Worksheets("Low").Cells(z, 6).Value = Worksheets("In Stock").Cells(20, 6).Value
Worksheets("Low").Cells(z, 7).Value = Worksheets("In Stock").Cells(20, 7).Value
Worksheets("Low").Cells(z, 8).Value = Worksheets("In Stock").Cells(20, 8).Value
Worksheets("Low").Cells(z, 9).Value = Worksheets("In Stock").Cells(20, 9).Value
Worksheets("Low").Cells(z, 10).Value = Worksheets("In Stock").Cells(20, 10).Value
Worksheets("Low").Cells(z, 11).Value = Worksheets("In Stock").Cells(20, 11).Value
Worksheets("Low").Cells(z, 12).Value = Worksheets("In Stock").Cells(20, 12).Value
Worksheets("Low").Cells(z, 13).Value = Worksheets("In Stock").Cells(20, 13).Value

z = z + 1

JMP2:
Next i
Worksheets("Low").Select

As you can see, it's a simple copy/paste based on an if but for some reason- the macro just copies the first line instead of skipping to the second line that is under 98%.

Also, instead of copying the full value of the data in the columns- I am just seeing zeros right now.

Many thanks for your help.

Answer 1

GoTo is generally considered the bane of modern society and should be avoided whenever possible. It makes code very difficult to follow for the person coming along behind you (or for you when you have to revisit it in 6 months). This will make your code much more readable:

Option Explicit
Dim SourceRow As Integer
Dim DestRow as Integer
Dim Col as Integer 

SourceRow = 3

For DestRow = 20 To Worksheets("In Stock").TextBox1.Value
  If Worksheets("In Stock").Cells(DestRow, 11) < 0.98 Then  
    With Worksheets("Low")
      For Col = 1 to 13
        .Cells(SourceRow, Col) = Worksheets("In Stock").Cells(DestRow, Col)
      Next
    End With
    SourceRow = SourceRow + 1
  End If
Next 

Worksheets("Low").Select

As was mentioned in the comments, since you're looking for a percentage, your If should be comparing to 0.98 , and since it's a numeric, there's no reason to put it in quotes "98" and force Excel to convert it from a string to a float every time.