一对多映射-使用XSLT从XML转换为CSV

Question

I am using XSL transformation to convert a XML file to CSV file.

I could get the identity attribute value in CSV file.But I want to get the repeated element's(Remark) attribute also.

My XML is:

<library>
  <book>
    <name identity="book1"/>
    <Remark id="1"/>
    <Remark id="2" />
  </book>
  <book>
    <name identity="book2"/>
    <Remark id="3"/>
    <Remark id="4" />
  </book>
</library>

I need a CSV as below:

name_identity,remark_id
book1,1
book1,2
book2,3
book2,4

Kindly advice on this.

Answer 1

Try it this way:

<xsl:template match="/library">
    <xsl:text>name_identity,remark_id&#10;</xsl:text>
    <xsl:for-each select="book/Remark">
        <xsl:value-of select="../name/@identity"/>
        <xsl:text>,</xsl:text>
        <xsl:value-of select="@id"/>
        <xsl:if test="position()!=last()">
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

Answer 2

If you are using XSLT 2.0, You could use grouping. The below code groups by name/@identity

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  xmlns:xs="http://www.w3.org/2001/XMLSchema" >
<xsl:output method="text"/>
<xsl:template match="/">
<xsl:text>name_identity,remark_id&#10;</xsl:text>
    <xsl:for-each-group select="/library/book" group-by="name/@identity">
        <xsl:for-each select="current-group()/Remark">
            <xsl:value-of select="current-grouping-key()"/>
            <xsl:text>,</xsl:text>
            <xsl:value-of select="@id"/>
            <xsl:if test="position() != last()">
                <xsl:text>&#10;</xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:if test="position() != last()">
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
    </xsl:for-each-group>
</xsl:template>
</xsl:stylesheet>