仅获取文本文件的一部分

Question

I am building a VB Parser and I have to parse VB classes as file.

Right now I'm proceeding like this:

Dim lines As List(Of String) = File.ReadAllLines(fileName).ToList()

Where fileName is the actual path of the vb class file to parse. However my main concern is that it actually get ALL the lines in the files.

So say that I have a vb.class that looks like this:

Public Class Class1VB


    Friend item1 As String
    Friend item2 As String
    Friend item3 As String
    Friend item4 As String
    Friend item5 As String
    Friend item6 As String

    Public Sub New()
        MyBase.new()
    End Sub

    Public Overrides Sub InstanciateVariables()

        item1 = New String()
        item2 = New String()
        item3 = New String()
        item4 = New String()
        item5 = New String()
        item6 = New String()

    End Sub

End Class

#End Region

And I only want the item located in the InstanciateVariables() Sub in the lines array, is there a way to do that using Linq or any VB logic available?

Answer 1

How long are your files? If they are not huge, you could load the contents of the entire file into a single string and then use String.IndexOf() to identify the location within the string where the "InstanciateVariables()" code appears. Next,locate the subsequent location where the "End sub" appears and then perform A string.substring() operation to pull out the desired contents.

Answer 2

您可以1）将整个列表放入ListOfAllLines，2）循环，逐行阅读每一行，直到找到显示“ InstanceVariables”的行，3）循环，从ListOfAllLines复制到ListOfImportantLines，直到“ End Sub”，4）停止读取ListOfAllLines并将其删除。

Answer 3

If you use File.ReadLines() , instead of File.ReadAllLines() , you get an IEnumerable(Of String) which you can use Linq to query, while reading the minimum number of lines required. eg This would get the contents of InstanciateVariables , without the Sub and End Sub lines, and would only read up to the End Sub line.

Dim lines = File.ReadLines(fileName)
Dim selectedLines = lines.
    SkipWhile(Function(x) Not x.Contains("InstanciateVariables()")).
    Skip(1).
    TakeWhile(Function(x) Not x.Contains("End Sub"))
For Each l In selectedLines
    Console.WriteLine(l)
Next

It still has to read all the lines before the Public Overrides Sub InstanciateVariables() line - I don't know of any way to avoid that.

If you want the Sub and End Sub lines it's a little more tricky, but you could create an extension method to take lines inclusively:

<Extension>
Public Iterator Function TakeUntilInclusive(Of T)(data As IEnumerable(Of T), predicate As Func(Of T, Boolean)) As IEnumerable(Of T)
    For Each item In data
        Yield item
        If predicate(item) Then
            Return
        End If
    Next
End Function

And then use that:

Dim lines = File.ReadLines(fileName)
Dim selectedLines = lines.
    SkipWhile(Function(x) Not x.Contains("InstanciateVariables()")).
    TakeUntilInclusive(Function(x) x.Contains("End Sub"))
For Each l In selectedLines
    Console.WriteLine(l)
Next