在vba中的功能中使用自动筛选

Question

The below function is throwing error 424 Object Required .

I want to use this in Worksheets asformula.

Data is available in Uploaded Report tab. Row 7 is the Header row .

Function Bookings(Start_date As Date, End_date As Date) As Long
    On Error GoTo Protection
    Dim l_row As Long
    Dim rngRow, resultRng, filterRng As Range
    Bookings = 0
    l_row = Worksheets("Uploaded Report").Cells(Rows.Count, 1).End(xlUp).Row

    Worksheets("Uploaded Report").AutoFilterMode = False

    Set filterRng = Worksheets("Uploaded Report").Range("A7:E" & l_row)
    filterRng.AutoFilter field:=1, Criteria1:="GC Hi Top", VisibleDropDown:=True
    'Worksheets("Uploaded Report").Range("A7:E" & l_row).AutoFilter Field:=3, Criteria1:=">=" & Format(Start_date, "mm/dd/yyyy"), Operator:=xlAnd, Criteria2:="<=" & Format(End_date, "mm/dd/yyyy")
    Worksheets("Uploaded Report").Activate
    Set resultRng = filterRng.AutoFilter.Range.SpecialCells(xlCellTypeVisible)

    For Each rngRow In resultRng
        If rngRow.Row = 7 Then
           GoTo NextIteration
        End If
        If Len(Worksheets("Uploaded Report").Range("A" & rngRow.Row).Value) > 0 Then
            If rngRow.Row > 1 And rngRow.Column = 3 Then
                Bookings = Bookings + 1
            End If
        End If

NextIteration: Next rngRow

Protection: MsgBox Err.Number & Err.Description

End Function

Answer 1

How to get rid of the error

When testing your code, the error was raised by the line:
Set resultRng = filterRng.AutoFilter.Range.SpecialCells(xlCellTypeVisible)

Change that line to :
Set resultRng = filterRng.SpecialCells(xlCellTypeVisible)

---

Other things

1. You have incorrectly declared variables i presume.

   Dim rngRow, resultRng, filterRng As Range
   change to
   Dim rngRow As Range, resultRng As Range, filterRng As Range

2. In the line for l_row , you are missing a parent for Rows.count
l_row = Worksheets("Uploaded Report").Cells(Rows.Count, 1).End(xlUp).Row
   change to
   l_row = Worksheets("Uploaded Report").Cells(Worksheets("Uploaded Report").Rows.Count, 1).End(xlUp).Row
   or use With...End With statement.

3. Are you sure you want Error handler in function? Without it it will just display excel error in the cell, without the MsgBox, which for clueless users is useless and scary. If you opt to keep the Error handler, add a line Exit Function before the Protection: label.

4. To be more efficient and to get rid of the redundant If...End If statements you can set the resultRng to
   Set resultRng = filterRng.Columns(3).SpecialCells(xlCellTypeVisible)
   This way you will only loop through column "C".