创建球拍错误消息

Question

I'm having a very hard time creating what should be a simple error message for a recursive function. I have this program:

(check-expect (rewrite '(x x x - x x x x) 3 'x)
       (list 'x 'x 'x 'x 'x 'x 'x 'x))
(check-error (rewrite '(5 4 3 2 1) 5 6) 
         "rewrite: 5 is too large for (5 4 3 2 1)")

(define (rewrite init-ls init-n init-val)
  (local [(define (help ls n val)
            (cond 
              [(zero? n) (cons val (rest ls))]
              [(empty? ls) (error 'rewrite 
                                       (format "~s is too large for ~s"
                                                init-n init-ls))]      
              [else (cons (first ls) 
                          (rewrite (rest ls) (sub1 n) val))]))]
        (help init-ls init-n init-val) ))

Basically it just replaces the element at position n of a list with the val (value) you choose. I can't get the error message to work at all though for when n is greater than the length of the list.

*I do not want to use (length list) because obviously that would be very slow when you start putting a large numbers of items in a list

I've tried using no local function, putting it above the (zero?), and outside the local function multiple ways but just can't get it to work. Any help would be great in ISL+

Answer 1

There are two small issues here. The first is that the clauses to check for zero? and empty? should be reversed, since the zero? case assumes a non-empty list.

The more important issue is probably just a typo. When you recur, you call rewrite itself, not help :

[else (cons (first ls) 
            (rewrite (rest ls) (sub1 n) val))]

You should be calling help instead, which will preserve the values of init-ls and init-n for use in your error message.

The fixed code looks like this:

(define (rewrite init-ls init-n init-val)
  (local [(define (help ls n val)
            (cond
              [(empty? ls) (error 'rewrite
                                  (format "~s is too large for ~s"
                                          init-n init-ls))]
              [(zero? n) (cons val (rest ls))]
              [else (cons (first ls)
                          (help (rest ls) (sub1 n) val))]))]
    (help init-ls init-n init-val)))