Arduino IDE-按下按钮时停止重复“ Serial.println”

Question

I'm working on a project where, when you press a button and it displays a value in the Serial Monitor (not the most exciting granted but this is my first none-tutorial project), the code for this is:

void loop() {

   if(digitalRead(firstButton) == HIGH) {    
      digitalWrite(firstLed, HIGH);    
      Serial.println("First button pressed");
      delay(250);
   }

   if(digitalRead(secondButton) == HIGH) {    
      digitalWrite(secondLed, HIGH);    
      Serial.println("Second button pressed");
      delay(250);
   }

}

This largely does what you would expect it to, however if you hold the button down it repeats the 'Serial.println' value continuously until the button is released. Ideally I need this to state the 'Serial.println' value once per press, regardless of whether it is held down for a second or a minute.

Any help would be greatly appreciated...

No idea if it matters but I'm using an Arduino Uno R3 with a Wi-Fi shield (which is giving me all kinds of grief but thats for another day).

Answer 1

In order to detect a keypress change, you need to detect the button state change event. In which case you need to keep track of the previous button state:

void loop() {

    static int firstPrevious = LOW;
    static int secondPrevious = LOW;

    int first = digitalRead(firstButton);
    int second = digitalRead(secondButton);

    if((first == HIGH) && (firstPrevious == LOW)) {
        digitalWrite(firstLed, HIGH);
        Serial.println("First button pressed");
        delay(250);
    }

    if((second == HIGH) && (secondPrevious == LOW)) {
        digitalWrite(secondLed, HIGH);
        Serial.println("Second button pressed");
        delay(250);
    }

    firstPrevious = first;
    secondPrevious = second;
}

After this, you'll want to look into switch "de-bounce" so you don't get multiple events for each keypress...