如何在列中查找值高于特定水平的最后一个单元格

Question

I have a file with temperature readings that increase, stay roughly level, then decrease. I need to find the last value at the plateau ( 121 ) before the cells decrease again. The code I've been trying is:

    Set rng = Range("P22:Q217")
For Each cll In rng
If cll.Value > 121 Then
    If cll.Row > first121row Then first121row = cll.Row
    Exit For
End If
Next
MsgBox first121row  

But this returns the first row with a value above 121 instead of the last row.

What am I doing wrong, or is there a better approach to this?

Answer 1

Start from the bottom and work upwards:

Sub dural()
    For i = 217 To 22 Step -1
        For Each a In Array("P", "Q")
            If Cells(i, a).Value > 121 Then
                MsgBox Cells(i, a).Row
                Exit Sub
            End If
        Next a
    Next i
End Sub

Answer 2

You have a known range of cells you want to search (could also be dynamically obtained) and a call to a standard worksheet function can retrieve the maximum value in the range. Using .Find backwards may be more efficient than a loop.

Sub last_MAX()
    Dim mx As Double, rng As Range, lst As Range
    Set rng = Range("P22:Q217")
    mx = Application.Max(rng)
    With rng
        'normally .Find deserves some error control but we KNOW the value is in there
        Set lst = .Find(what:=mx, after:=.Cells(1, 1), LookIn:=xlValues, lookat:=xlWhole, _
                        SearchOrder:=xlByRows, SearchDirection:=xlPrevious)
        Debug.Print "Last " & mx & "° found at row " & lst.row & " at " & lst.Address(0, 0)
    End With
End Sub

By retrieving the maximum value just prior to the reverse search we can forego error control. That is not normally a good idea with a VBA .Find but we know the value is there in this case.